dev-libs/opencryptoki/opencryptoki-3.4.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools multilib flag-o-matic user
   7
   8 DESCRIPTION="PKCS#11 provider cryptographic hardware"
   9 HOMEPAGE="https://sourceforge.net/projects/opencryptoki"
  10 SRC_URI="mirror://sourceforge/opencryptoki/${PV}/${PN}-v${PV}.tgz"
  11
  12 # Upstream is looking into relicensing it into CPL-1.0 entirely; the CCA
  13 # token sources are under CPL-1.0 already.
  14 LICENSE="CPL-0.5"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~s390 ~x86"
  17 IUSE="debug libressl +tpm"
  18
  19 RDEPEND="tpm? ( app-crypt/trousers )
  20         !libressl? ( dev-libs/openssl:0= )
  21         libressl? ( dev-libs/libressl:0= )"
  22 DEPEND="${RDEPEND}"
  23
  24 DOCS=(
  25         README AUTHORS FAQ TODO
  26         doc/openCryptoki-HOWTO.pdf
  27 )
  28
  29 # tests right now basically don't exist; the only available thing would
  30 # test against an installed copy and would kill a running pcscd, all
  31 # things that we're not interested to.
  32 RESTRICT=test
  33
  34 S="${WORKDIR}/${PN}"
  35
  36 pkg_setup() {
  37         enewgroup pkcs11
  38 }
  39
  40 src_prepare() {
  41         default
  42         mv configure.in configure.ac || die
  43         eautoreconf
  44 }
  45
  46 src_configure() {
  47         # package uses ${localstatedir}/lib as the default path, so if we
  48         # leave it to econf, it'll create /var/lib/lib.
  49
  50         # Since upstream by default seem to enable any possible token, even
  51         # when they don't seem to be used, we limit ourselves to the
  52         # software emulation token (swtok) and if the user enabled the tpm
  53         # USE flag, tpmtok.  The rest of the tokens seem to be hardware- or
  54         # software-dependent even when they build fine without their
  55         # requirements, but until somebody asks for those, I'd rather not
  56         # enable them.
  57
  58         # We don't use --enable-debug because that tinkers with the CFLAGS
  59         # and we don't want that. Instead we append -DDEBUG which enables
  60         # debug information.
  61         use debug && append-flags -DDEBUG
  62
  63         econf \
  64                 --localstatedir=/var \
  65                 --enable-fast-install \
  66                 --disable-dependency-tracking \
  67                 --disable-debug \
  68                 --enable-daemon \
  69                 --enable-library \
  70                 --disable-icatok \
  71                 --enable-swtok \
  72                 $(use_enable tpm tpmtok) \
  73                 --disable-ccatok
  74 }
  75
  76 src_install() {
  77         default
  78         find "${ED}" -name '*.la' -delete || die
  79
  80         # Install libopencryptoki in the standard directory for libraries.
  81         mv "${ED}"/usr/$(get_libdir)/opencryptoki/libopencryptoki.so* "${ED}"/usr/$(get_libdir) || die
  82         rm "${ED}"/usr/$(get_libdir)/pkcs11/libopencryptoki.so
  83         dosym ../libopencryptoki.so /usr/$(get_libdir)/pkcs11/libopencryptoki.so
  84
  85         # Remove compatibility symlinks as we _never_ required those and
  86         # they seem unused even upstream.
  87         find "${ED}" -name 'PKCS11_*' -delete
  88
  89         # We replace their ld.so and init files (mostly designed for RedHat
  90         # as far as I can tell) with our own replacements.
  91         rm -rf "${ED}"/etc/ld.so.conf.d "${ED}"/etc/rc.d
  92
  93         # make sure that we don't modify the init script if the USE flags
  94         # are enabled for the needed services.
  95         cp "${FILESDIR}"/pkcsslotd.init.2 "${T}"/pkcsslotd.init
  96         use tpm || sed -i -e '/use tcsd/d' "${T}"/pkcsslotd.init
  97         newinitd "${T}/pkcsslotd.init" pkcsslotd
  98
  99         # We create /var dirs at runtime as needed, so don't bother installing
 100         # our own.
 101         rm -r "${ED}"/var/{lib,lock} || die
 102 }