dev-libs/mpfr/mpfr-3.1.6.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 # NOTE: we cannot depend on autotools here starting with gcc-4.3.x
   7 inherit eutils libtool multilib-minimal
   8
   9 MY_PV=${PV/_p*}
  10 MY_P=${PN}-${MY_PV}
  11 PLEVEL=${PV/*p}
  12 DESCRIPTION="library for multiple-precision floating-point computations with exact rounding"
  13 HOMEPAGE="https://www.mpfr.org/"
  14 SRC_URI="https://www.mpfr.org/mpfr-${MY_PV}/${MY_P}.tar.xz"
  15
  16 LICENSE="LGPL-2.1"
  17 SLOT="0/4" # libmpfr.so version
  18 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  19 IUSE="static-libs"
  20
  21 RDEPEND=">=dev-libs/gmp-4.1.4-r2[${MULTILIB_USEDEP},static-libs?]"
  22 DEPEND="${RDEPEND}"
  23
  24 S=${WORKDIR}/${MY_P}
  25
  26 src_prepare() {
  27         if [[ ${PLEVEL} != ${PV} ]] ; then
  28                 local i
  29                 for (( i = 1; i <= PLEVEL; ++i )) ; do
  30                         epatch "${FILESDIR}"/${MY_PV}/patch$(printf '%02d' ${i})
  31                 done
  32         fi
  33         epatch_user
  34         find . -type f -exec touch -r configure {} +
  35         elibtoolize
  36 }
  37
  38 multilib_src_configure() {
  39         # Make sure mpfr doesn't go probing toolchains it shouldn't #476336#19
  40         ECONF_SOURCE=${S} \
  41         user_redefine_cc=yes \
  42         econf \
  43                 --docdir="\$(datarootdir)/doc/${PF}" \
  44                 $(use_enable static-libs static)
  45 }
  46
  47 multilib_src_install_all() {
  48         use static-libs || find "${ED}"/usr -name '*.la' -delete
  49
  50         # clean up html/license install
  51         pushd "${ED}"/usr/share/doc/${PF} >/dev/null || die
  52         dohtml *.html && rm COPYING* *.html
  53         popd >/dev/null || die
  54 }