dev-libs/mpfr/mpfr-3.1.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="4"
   5
   6 # NOTE: we cannot depend on autotools here starting with gcc-4.3.x
   7 inherit eutils libtool multilib-minimal
   8
   9 MY_PV=${PV/_p*}
  10 MY_P=${PN}-${MY_PV}
  11 PLEVEL=${PV/*p}
  12 DESCRIPTION="library for multiple-precision floating-point computations with exact rounding"
  13 HOMEPAGE="https://www.mpfr.org/"
  14 SRC_URI="https://www.mpfr.org/mpfr-${MY_PV}/${MY_P}.tar.xz"
  15
  16 LICENSE="LGPL-2.1"
  17 SLOT="0"
  18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  19 IUSE="static-libs"
  20
  21 RDEPEND=">=dev-libs/gmp-4.1.4-r2[${MULTILIB_USEDEP},static-libs?]"
  22 DEPEND="${RDEPEND}"
  23
  24 S=${WORKDIR}/${MY_P}
  25
  26 src_prepare() {
  27         if [[ ${PLEVEL} != ${PV} ]] ; then
  28                 local i
  29                 for (( i = 1; i <= PLEVEL; ++i )) ; do
  30                         epatch "${FILESDIR}"/${MY_PV}/patch$(printf '%02d' ${i})
  31                 done
  32         fi
  33         epatch "${FILESDIR}"/${P}-cygwin.patch #579840
  34         epatch_user
  35         find . -type f -exec touch -r configure {} +
  36         elibtoolize
  37 }
  38
  39 multilib_src_configure() {
  40         # Make sure mpfr doesn't go probing toolchains it shouldn't #476336#19
  41         ECONF_SOURCE=${S} \
  42         user_redefine_cc=yes \
  43         econf \
  44                 --docdir="\$(datarootdir)/doc/${PF}" \
  45                 $(use_enable static-libs static)
  46 }
  47
  48 multilib_src_install_all() {
  49         use static-libs || find "${ED}"/usr -name '*.la' -delete
  50
  51         # clean up html/license install
  52         pushd "${ED}"/usr/share/doc/${PF} >/dev/null
  53         dohtml *.html
  54         rm COPYING* *.html || die
  55         popd >/dev/null
  56 }