dev-libs/m17n-lib/m17n-lib-1.7.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Multilingual Library for Unix/Linux"
   9 HOMEPAGE="https://savannah.nongnu.org/projects/m17n https://git.savannah.nongnu.org/cgit/m17n/m17n-lib.git"
  10 SRC_URI="mirror://nongnu/m17n/${P}.tar.gz"
  11
  12 LICENSE="LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 sparc x86"
  15 IUSE="X anthy athena bidi fontconfig gd libotf libxml2 spell xft"
  16
  17 RDEPEND="~dev-db/m17n-db-${PV}
  18         X? (
  19                 x11-libs/libX11
  20                 athena? ( x11-libs/libXaw )
  21                 bidi? ( dev-libs/fribidi )
  22                 fontconfig? ( media-libs/fontconfig )
  23                 gd? ( media-libs/gd[png] )
  24                 libotf? ( dev-libs/libotf )
  25                 xft? (
  26                         media-libs/freetype
  27                         x11-libs/libXft
  28                 )
  29         )
  30         anthy? ( app-i18n/anthy )
  31         libxml2? ( dev-libs/libxml2 )
  32         spell? ( app-text/aspell )"
  33 DEPEND="${RDEPEND}
  34         virtual/pkgconfig"
  35
  36 PATCHES=(
  37         "${FILESDIR}"/${PN}-configure.patch
  38         "${FILESDIR}"/${PN}-freetype.patch
  39         "${FILESDIR}"/${PN}-ispell.patch
  40         "${FILESDIR}"/${PN}-parallel-make.patch
  41 )
  42
  43 src_prepare() {
  44         default
  45
  46         eautoreconf
  47         # workaround for parallel install
  48         sed -i "/^install-module/s/:/: install-libLTLIBRARIES/" src/Makefile.in
  49 }
  50
  51 src_configure() {
  52         local myconf=(
  53                 $(use_with anthy)
  54                 $(use_with libxml2)
  55                 $(use_with spell ispell)
  56         )
  57         if use X; then
  58                 myconf+=(
  59                         $(use_with athena)
  60                         $(use_with bidi fribidi)
  61                         $(use_with fontconfig)
  62                         $(use_with xft freetype)
  63                         $(use_with gd)
  64                         --with-gui
  65                         $(use_with libotf)
  66                         --with-x
  67                         $(use_with xft)
  68                 )
  69         else
  70                 myconf+=(
  71                         --without-athena
  72                         --without-fontconfig
  73                         --without-freetype
  74                         --without-fribidi
  75                         --without-gd
  76                         --without-gui
  77                         --without-libotf
  78                         --without-x
  79                         --without-xft
  80                 )
  81         fi
  82
  83         econf "${myconf[@]}"
  84 }