dev-libs/log4cxx/log4cxx-0.10.0-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P=apache-${P}
   7
   8 DESCRIPTION="Library of C++ classes for logging to files, syslog and other destinations"
   9 HOMEPAGE="http://logging.apache.org/log4cxx/"
  10 SRC_URI="mirror://apache/logging/${PN}/${PV}/${MY_P}.tar.gz"
  11
  12 LICENSE="Apache-2.0"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~ppc-macos"
  15 IUSE="iodbc unicode odbc smtp"
  16
  17 RDEPEND="dev-libs/apr:1
  18         dev-libs/apr-util:1
  19         odbc? (
  20                 iodbc? ( >=dev-db/libiodbc-3.52.4 )
  21                 !iodbc? ( dev-db/unixODBC ) )
  22         smtp? ( net-libs/libesmtp )"
  23 DEPEND="${RDEPEND}"
  24
  25 S="${WORKDIR}/${MY_P}"
  26
  27 # test suite fails
  28 RESTRICT="test"
  29
  30 HTML_DOCS=( site/. )
  31 PATCHES=(
  32         "${FILESDIR}/${PN}-0.10.0-missing_includes.patch"
  33         "${FILESDIR}/${PN}-0.10.0-gcc44.patch"
  34         "${FILESDIR}/${PN}-0.10.0-unixODBC.patch"
  35         "${FILESDIR}/${PN}-0.10.0-fix-c++14.patch"
  36 )
  37
  38 pkg_setup() {
  39         if use iodbc && ! use odbc; then
  40                 elog "Please enable the odbc USE-flag as well if you want odbc-support through iodbc."
  41         fi
  42 }
  43
  44 src_configure() {
  45         econf \
  46                 --disable-doxygen \
  47                 --disable-html-docs \
  48                 --with-apr-util="${SYSROOT}${EPREFIX}/usr" \
  49                 $(use_with smtp SMTP libesmtp) \
  50                 $(use_with odbc ODBC $(usex iodbc iODBC unixODBC)) \
  51                 --with-charset=$(usex unicode utf-8 auto)
  52 }
  53
  54 src_install() {
  55         default
  56
  57         docinto examples
  58         dodoc src/examples/cpp/*.cpp
  59         docompress -x /usr/share/doc/${PF}/examples
  60
  61         # package provides .pc files
  62         find "${D}" -name '*.la' -delete || die
  63 }