dev-libs/libzip/libzip-1.6.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake multibuild
   7
   8 DESCRIPTION="Library for manipulating zip archives"
   9 HOMEPAGE="https://nih.at/libzip/"
  10 SRC_URI="https://www.nih.at/libzip/${P}.tar.xz"
  11
  12 LICENSE="BSD"
  13 SLOT="0/5"
  14 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ~ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-macos"
  15 IUSE="bzip2 doc gnutls libressl lzma mbedtls ssl static-libs test"
  16 RESTRICT="!test? ( test )"
  17
  18 DEPEND="
  19         sys-libs/zlib
  20         bzip2? ( app-arch/bzip2:= )
  21         lzma? ( app-arch/lzma:= )
  22         ssl? (
  23                 gnutls? (
  24                         dev-libs/nettle:0=
  25                         >=net-libs/gnutls-3.6.5:=
  26                 )
  27                 !gnutls? (
  28                         mbedtls? ( net-libs/mbedtls:= )
  29                         !mbedtls? (
  30                                 !libressl? ( dev-libs/openssl:0= )
  31                                 libressl? ( dev-libs/libressl:0= )
  32                         )
  33                 )
  34         )
  35 "
  36 RDEPEND="${DEPEND}"
  37
  38 pkg_setup() {
  39         # Upstream doesn't support building dynamic & static
  40         # simultaneously: https://github.com/nih-at/libzip/issues/76
  41         MULTIBUILD_VARIANTS=( shared $(usev static-libs) )
  42 }
  43
  44 src_configure() {
  45         myconfigure() {
  46                 local mycmakeargs=(
  47                         -DBUILD_EXAMPLES=OFF # nothing is installed
  48                         -DENABLE_COMMONCRYPTO=OFF # not in tree
  49                         -DENABLE_BZIP2=$(usex bzip2)
  50                         -DENABLE_LZMA=$(usex lzma)
  51                 )
  52                 if [[ ${MULTIBUILD_VARIANT} = static-libs ]]; then
  53                         mycmakeargs+=(
  54                                 -DBUILD_DOC=OFF
  55                                 -DBUILD_EXAMPLES=OFF
  56                                 -DBUILD_SHARED_LIBS=OFF
  57                                 -DBUILD_TOOLS=OFF
  58                         )
  59                 else
  60                         mycmakeargs+=(
  61                                 -DBUILD_DOC=$(usex doc)
  62                                 -DBUILD_REGRESS=$(usex test)
  63                         )
  64                 fi
  65
  66                 if use ssl; then
  67                         if use gnutls; then
  68                                 mycmakeargs+=(
  69                                         -DENABLE_GNUTLS=$(usex gnutls)
  70                                         -DENABLE_MBEDTLS=OFF
  71                                         -DENABLE_OPENSSL=OFF
  72                                 )
  73                         elif use mbedtls; then
  74                                 mycmakeargs+=(
  75                                         -DENABLE_GNUTLS=OFF
  76                                         -DENABLE_MBEDTLS=$(usex mbedtls)
  77                                         -DENABLE_OPENSSL=OFF
  78                                 )
  79                         else
  80                                 mycmakeargs+=(
  81                                         -DENABLE_GNUTLS=OFF
  82                                         -DENABLE_MBEDTLS=OFF
  83                                         -DENABLE_OPENSSL=ON
  84                                 )
  85                         fi
  86                 else
  87                         mycmakeargs+=(
  88                                 -DENABLE_GNUTLS=OFF
  89                                 -DENABLE_MBEDTLS=OFF
  90                                 -DENABLE_OPENSSL=OFF
  91                         )
  92                 fi
  93                 cmake_src_configure
  94         }
  95
  96         multibuild_foreach_variant myconfigure
  97 }
  98
  99 src_compile() {
 100         multibuild_foreach_variant cmake_src_compile
 101 }
 102
 103 src_test() {
 104         [[ ${MULTIBUILD_VARIANT} = shared ]] && cmake_src_test
 105 }
 106
 107 src_install() {
 108         multibuild_foreach_variant cmake_src_install
 109 }