dev-libs/libxslt/libxslt-1.1.32.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6 PYTHON_REQ_USE="xml"
   7
   8 inherit autotools ltprune python-r1 toolchain-funcs multilib-minimal
   9
  10 DESCRIPTION="XSLT libraries and tools"
  11 HOMEPAGE="http://www.xmlsoft.org/"
  12 SRC_URI="ftp://xmlsoft.org/${PN}/${P}.tar.gz"
  13
  14 LICENSE="MIT"
  15 SLOT="0"
  16 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17
  18 IUSE="crypt debug examples python static-libs elibc_Darwin"
  19 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  20
  21 RDEPEND="
  22         >=dev-libs/libxml2-2.9.1-r5:2[${MULTILIB_USEDEP}]
  23         crypt?  ( >=dev-libs/libgcrypt-1.5.3:0=[${MULTILIB_USEDEP}] )
  24         python? (
  25                 ${PYTHON_DEPS}
  26                 dev-libs/libxml2:2[python,${PYTHON_USEDEP}] )
  27 "
  28 DEPEND="${RDEPEND}"
  29
  30 MULTILIB_CHOST_TOOLS=(
  31         /usr/bin/xslt-config
  32 )
  33
  34 MULTILIB_WRAPPED_HEADERS=(
  35         /usr/include/libxslt/xsltconfig.h
  36 )
  37
  38 src_prepare() {
  39         default
  40
  41         DOCS=( AUTHORS ChangeLog FEATURES NEWS README TODO )
  42
  43         # Simplify python setup
  44         # https://bugzilla.gnome.org/show_bug.cgi?id=758095
  45         eapply "${FILESDIR}"/${PV}-simplify-python.patch
  46         eapply "${FILESDIR}"/${PN}-1.1.28-disable-static-modules.patch
  47
  48         eautoreconf
  49         # If eautoreconf'd with new autoconf, then epunt_cxx is not necessary
  50         # and it is propably otherwise too if upstream generated with new
  51         # autoconf
  52 #       epunt_cxx
  53         # But Prefix always needs elibtoolize if not eautoreconf'd.
  54 #       elibtoolize
  55 }
  56
  57 multilib_src_configure() {
  58         libxslt_configure() {
  59                 ECONF_SOURCE="${S}" econf \
  60                         --with-html-dir="${EPREFIX}"/usr/share/doc/${PF} \
  61                         --with-html-subdir=html \
  62                         $(use_with crypt crypto) \
  63                         $(use_with debug) \
  64                         $(use_with debug mem-debug) \
  65                         $(use_enable static-libs static) \
  66                         "$@"
  67         }
  68
  69         libxslt_py_configure() {
  70                 mkdir -p "${BUILD_DIR}" || die # ensure python build dirs exist
  71                 run_in_build_dir libxslt_configure --with-python
  72         }
  73
  74         libxslt_configure --without-python # build python bindings separately
  75
  76         if multilib_is_native_abi && use python; then
  77                 python_foreach_impl libxslt_py_configure
  78         fi
  79 }
  80
  81 multilib_src_compile() {
  82         default
  83         multilib_is_native_abi && use python && libxslt_foreach_py_emake all
  84 }
  85
  86 multilib_src_test() {
  87         default
  88         multilib_is_native_abi && use python && libxslt_foreach_py_emake test
  89 }
  90
  91 multilib_src_install() {
  92         # "default" does not work here - docs are installed by multilib_src_install_all
  93         emake DESTDIR="${D}" install
  94
  95         if multilib_is_native_abi && use python; then
  96                 libxslt_foreach_py_emake \
  97                         DESTDIR="${D}" \
  98                         docsdir="${EPREFIX}"/usr/share/doc/${PF}/python \
  99                         EXAMPLE_DIR="${EPREFIX}"/usr/share/doc/${PF}/python/examples \
 100                         install
 101                 python_foreach_impl python_optimize
 102         fi
 103 }
 104
 105 multilib_src_install_all() {
 106         einstalldocs
 107
 108         if ! use examples && use python; then
 109                 rm -r "${ED}"/usr/share/doc/${PF}/python/examples || die
 110         fi
 111
 112         prune_libtool_files --modules
 113 }
 114
 115 libxslt_foreach_py_emake() {
 116         libxslt_py_emake() {
 117                 pushd "${BUILD_DIR}/python" > /dev/null || die
 118                 emake "$@"
 119                 popd > /dev/null
 120         }
 121         local native_builddir=${BUILD_DIR}
 122         python_foreach_impl libxslt_py_emake top_builddir="${native_builddir}" "$@"
 123 }