dev-libs/libxml2/libxml2-2.9.9-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} )
   7 PYTHON_REQ_USE="xml"
   8
   9 inherit libtool flag-o-matic ltprune python-r1 autotools prefix multilib-minimal
  10
  11 DESCRIPTION="XML C parser and toolkit"
  12 HOMEPAGE="http://www.xmlsoft.org/"
  13
  14 LICENSE="MIT"
  15 SLOT="2"
  16 KEYWORDS="alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 ~sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="debug examples icu ipv6 lzma python readline static-libs test"
  18 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  19
  20 XSTS_HOME="http://www.w3.org/XML/2004/xml-schema-test-suite"
  21 XSTS_NAME_1="xmlschema2002-01-16"
  22 XSTS_NAME_2="xmlschema2004-01-14"
  23 XSTS_TARBALL_1="xsts-2002-01-16.tar.gz"
  24 XSTS_TARBALL_2="xsts-2004-01-14.tar.gz"
  25 XMLCONF_TARBALL="xmlts20080827.tar.gz"
  26
  27 SRC_URI="ftp://xmlsoft.org/${PN}/${PN}-${PV/_rc/-rc}.tar.gz
  28         https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz
  29         test? (
  30                 ${XSTS_HOME}/${XSTS_NAME_1}/${XSTS_TARBALL_1}
  31                 ${XSTS_HOME}/${XSTS_NAME_2}/${XSTS_TARBALL_2}
  32                 http://www.w3.org/XML/Test/${XMLCONF_TARBALL} )"
  33
  34 RDEPEND="
  35         >=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
  36         icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
  37         lzma? ( >=app-arch/xz-utils-5.0.5-r1:=[${MULTILIB_USEDEP}] )
  38         python? ( ${PYTHON_DEPS} )
  39         readline? ( sys-libs/readline:= )
  40 "
  41 DEPEND="${RDEPEND}
  42         dev-util/gtk-doc-am
  43         virtual/pkgconfig
  44         hppa? ( >=sys-devel/binutils-2.15.92.0.2 )
  45 "
  46
  47 S="${WORKDIR}/${PN}-${PV%_rc*}"
  48
  49 MULTILIB_CHOST_TOOLS=(
  50         /usr/bin/xml2-config
  51 )
  52
  53 src_unpack() {
  54         # ${A} isn't used to avoid unpacking of test tarballs into $WORKDIR,
  55         # as they are needed as tarballs in ${S}/xstc instead and not unpacked
  56         unpack ${P/_rc/-rc}.tar.gz
  57         unpack ${P}-patchset.tar.xz
  58         cd "${S}" || die
  59
  60         if use test; then
  61                 cp "${DISTDIR}/${XSTS_TARBALL_1}" \
  62                         "${DISTDIR}/${XSTS_TARBALL_2}" \
  63                         "${S}"/xstc/ \
  64                         || die "Failed to install test tarballs"
  65                 unpack ${XMLCONF_TARBALL}
  66         fi
  67 }
  68
  69 src_prepare() {
  70         default
  71
  72         DOCS=( AUTHORS ChangeLog NEWS README* TODO* )
  73
  74         # Selective cherry-picks from master up to 2019-02-28 (commit 8161b463f5)
  75         eapply "${WORKDIR}"/patches
  76
  77         # Patches needed for prefix support
  78         eapply "${FILESDIR}"/${PN}-2.7.1-catalog_path.patch
  79
  80         eprefixify catalog.c xmlcatalog.c runtest.c xmllint.c
  81
  82         # Fix build for Windows platform
  83         # https://bugzilla.gnome.org/show_bug.cgi?id=760456
  84         # eapply "${FILESDIR}"/${PN}-2.8.0_rc1-winnt.patch
  85
  86         # Fix python detection, bug #567066
  87         # https://bugzilla.gnome.org/show_bug.cgi?id=760458
  88         eapply "${FILESDIR}"/${PN}-2.9.2-python-ABIFLAG.patch
  89
  90         # Fix python tests when building out of tree #565576
  91         eapply "${FILESDIR}"/${PN}-2.9.8-out-of-tree-test.patch
  92
  93         if [[ ${CHOST} == *-darwin* ]] ; then
  94                 # Avoid final linking arguments for python modules
  95                 sed -i -e '/PYTHON_LIBS/s/ldflags/libs/' configure.ac || die
  96                 # gcc-apple doesn't grok -Wno-array-bounds
  97                 sed -i -e 's/-Wno-array-bounds//' configure.ac || die
  98         fi
  99
 100         # Please do not remove, as else we get references to PORTAGE_TMPDIR
 101         # in /usr/lib/python?.?/site-packages/libxml2mod.la among things.
 102         # We now need to run eautoreconf at the end to prevent maintainer mode.
 103 #       elibtoolize
 104 #       epunt_cxx # if we don't eautoreconf
 105
 106         eautoreconf
 107 }
 108
 109 multilib_src_configure() {
 110         # filter seemingly problematic CFLAGS (#26320)
 111         filter-flags -fprefetch-loop-arrays -funroll-loops
 112
 113         # USE zlib support breaks gnome2
 114         # (libgnomeprint for instance fails to compile with
 115         # fresh install, and existing) - <azarah@gentoo.org> (22 Dec 2002).
 116
 117         # The meaning of the 'debug' USE flag does not apply to the --with-debug
 118         # switch (enabling the libxml2 debug module). See bug #100898.
 119
 120         # --with-mem-debug causes unusual segmentation faults (bug #105120).
 121
 122         libxml2_configure() {
 123                 ECONF_SOURCE="${S}" econf \
 124                         --with-html-subdir=${PF}/html \
 125                         $(use_with debug run-debug) \
 126                         $(use_with icu) \
 127                         $(use_with lzma) \
 128                         $(use_enable ipv6) \
 129                         $(use_enable static-libs static) \
 130                         $(multilib_native_use_with readline) \
 131                         $(multilib_native_use_with readline history) \
 132                         "$@"
 133         }
 134
 135         libxml2_py_configure() {
 136                 mkdir -p "${BUILD_DIR}" || die # ensure python build dirs exist
 137                 run_in_build_dir libxml2_configure "--with-python=${ROOT%/}${PYTHON}" # odd build system, also see bug #582130
 138         }
 139
 140         libxml2_configure --without-python # build python bindings separately
 141
 142         if multilib_is_native_abi && use python; then
 143                 python_foreach_impl libxml2_py_configure
 144         fi
 145 }
 146
 147 multilib_src_compile() {
 148         default
 149         if multilib_is_native_abi && use python; then
 150                 local native_builddir=${BUILD_DIR}
 151                 python_foreach_impl libxml2_py_emake top_builddir="${native_builddir}" all
 152         fi
 153 }
 154
 155 multilib_src_test() {
 156         ln -s "${S}"/xmlconf || die
 157         emake check || die "tests failed"
 158         multilib_is_native_abi && use python && python_foreach_impl libxml2_py_emake test
 159 }
 160
 161 multilib_src_install() {
 162         emake DESTDIR="${D}" \
 163                 EXAMPLES_DIR="${EPREFIX}"/usr/share/doc/${PF}/examples install
 164
 165         if multilib_is_native_abi && use python; then
 166                 python_foreach_impl libxml2_py_emake \
 167                         DESTDIR="${D}" \
 168                         docsdir="${EPREFIX}"/usr/share/doc/${PF}/python \
 169                         exampledir="${EPREFIX}"/usr/share/doc/${PF}/python/examples \
 170                         install
 171                 python_foreach_impl python_optimize
 172         fi
 173 }
 174
 175 multilib_src_install_all() {
 176         # on windows, xmllint is installed by interix libxml2 in parent prefix.
 177         # this is the version to use. the native winnt version does not support
 178         # symlinks, which makes repoman fail if the portage tree is linked in
 179         # from another location (which is my default). -- mduft
 180         if [[ ${CHOST} == *-winnt* ]]; then
 181                 rm -rf "${ED}"/usr/bin/xmllint
 182                 rm -rf "${ED}"/usr/bin/xmlcatalog
 183         fi
 184
 185         rm -rf "${ED}"/usr/share/doc/${P}
 186         einstalldocs
 187
 188         if ! use examples; then
 189                 rm -rf "${ED}"/usr/share/doc/${PF}/examples
 190                 rm -rf "${ED}"/usr/share/doc/${PF}/python/examples
 191         fi
 192
 193         prune_libtool_files --modules
 194 }
 195
 196 pkg_postinst() {
 197         # We don't want to do the xmlcatalog during stage1, as xmlcatalog will not
 198         # be in / and stage1 builds to ROOT=/tmp/stage1root. This fixes bug #208887.
 199         if [[ "${ROOT}" != "/" ]]; then
 200                 elog "Skipping XML catalog creation for stage building (bug #208887)."
 201         else
 202                 # need an XML catalog, so no-one writes to a non-existent one
 203                 CATALOG="${EROOT}etc/xml/catalog"
 204
 205                 # we dont want to clobber an existing catalog though,
 206                 # only ensure that one is there
 207                 # <obz@gentoo.org>
 208                 if [[ ! -e ${CATALOG} ]]; then
 209                         [[ -d "${EROOT}etc/xml" ]] || mkdir -p "${EROOT}etc/xml"
 210                         "${EPREFIX}"/usr/bin/xmlcatalog --create > "${CATALOG}"
 211                         einfo "Created XML catalog in ${CATALOG}"
 212                 fi
 213         fi
 214 }
 215
 216 libxml2_py_emake() {
 217         pushd "${BUILD_DIR}/python" > /dev/null || die
 218         emake "$@"
 219         popd > /dev/null
 220 }