dev-libs/libxml2/libxml2-2.9.8.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
   6 PYTHON_REQ_USE="xml"
   7
   8 inherit libtool flag-o-matic ltprune python-r1 autotools prefix multilib-minimal
   9
  10 DESCRIPTION="XML C parser and toolkit"
  11 HOMEPAGE="http://www.xmlsoft.org/"
  12
  13 LICENSE="MIT"
  14 SLOT="2"
  15 KEYWORDS="alpha amd64 arm arm64 ~hppa ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="debug examples icu ipv6 lzma python readline static-libs test"
  17 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  18
  19 XSTS_HOME="http://www.w3.org/XML/2004/xml-schema-test-suite"
  20 XSTS_NAME_1="xmlschema2002-01-16"
  21 XSTS_NAME_2="xmlschema2004-01-14"
  22 XSTS_TARBALL_1="xsts-2002-01-16.tar.gz"
  23 XSTS_TARBALL_2="xsts-2004-01-14.tar.gz"
  24 XMLCONF_TARBALL="xmlts20080827.tar.gz"
  25
  26 SRC_URI="ftp://xmlsoft.org/${PN}/${PN}-${PV/_rc/-rc}.tar.gz
  27         test? (
  28                 ${XSTS_HOME}/${XSTS_NAME_1}/${XSTS_TARBALL_1}
  29                 ${XSTS_HOME}/${XSTS_NAME_2}/${XSTS_TARBALL_2}
  30                 http://www.w3.org/XML/Test/${XMLCONF_TARBALL} )"
  31
  32 RDEPEND="
  33         >=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
  34         icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
  35         lzma? ( >=app-arch/xz-utils-5.0.5-r1:=[${MULTILIB_USEDEP}] )
  36         python? ( ${PYTHON_DEPS} )
  37         readline? ( sys-libs/readline:= )
  38 "
  39 DEPEND="${RDEPEND}
  40         dev-util/gtk-doc-am
  41         virtual/pkgconfig
  42         hppa? ( >=sys-devel/binutils-2.15.92.0.2 )
  43 "
  44
  45 S="${WORKDIR}/${PN}-${PV%_rc*}"
  46
  47 MULTILIB_CHOST_TOOLS=(
  48         /usr/bin/xml2-config
  49 )
  50
  51 src_unpack() {
  52         # ${A} isn't used to avoid unpacking of test tarballs into $WORKDIR,
  53         # as they are needed as tarballs in ${S}/xstc instead and not unpacked
  54         unpack ${P/_rc/-rc}.tar.gz
  55         cd "${S}" || die
  56
  57         if use test; then
  58                 cp "${DISTDIR}/${XSTS_TARBALL_1}" \
  59                         "${DISTDIR}/${XSTS_TARBALL_2}" \
  60                         "${S}"/xstc/ \
  61                         || die "Failed to install test tarballs"
  62                 unpack ${XMLCONF_TARBALL}
  63         fi
  64 }
  65
  66 src_prepare() {
  67         default
  68
  69         DOCS=( AUTHORS ChangeLog NEWS README* TODO* )
  70
  71         # Patches needed for prefix support
  72         eapply "${FILESDIR}"/${PN}-2.7.1-catalog_path.patch
  73
  74         eprefixify catalog.c xmlcatalog.c runtest.c xmllint.c
  75
  76         # Fix build for Windows platform
  77         # https://bugzilla.gnome.org/show_bug.cgi?id=760456
  78         # eapply "${FILESDIR}"/${PN}-2.8.0_rc1-winnt.patch
  79
  80         # Fix python detection, bug #567066
  81         # https://bugzilla.gnome.org/show_bug.cgi?id=760458
  82         eapply "${FILESDIR}"/${PN}-2.9.2-python-ABIFLAG.patch
  83
  84         if [[ ${CHOST} == *-darwin* ]] ; then
  85                 # Avoid final linking arguments for python modules
  86                 sed -i -e '/PYTHON_LIBS/s/ldflags/libs/' configure.ac || die
  87                 # gcc-apple doesn't grok -Wno-array-bounds
  88                 sed -i -e 's/-Wno-array-bounds//' configure.ac || die
  89         fi
  90
  91         # Please do not remove, as else we get references to PORTAGE_TMPDIR
  92         # in /usr/lib/python?.?/site-packages/libxml2mod.la among things.
  93         # We now need to run eautoreconf at the end to prevent maintainer mode.
  94 #       elibtoolize
  95 #       epunt_cxx # if we don't eautoreconf
  96
  97         eautoreconf
  98 }
  99
 100 multilib_src_configure() {
 101         # filter seemingly problematic CFLAGS (#26320)
 102         filter-flags -fprefetch-loop-arrays -funroll-loops
 103
 104         # USE zlib support breaks gnome2
 105         # (libgnomeprint for instance fails to compile with
 106         # fresh install, and existing) - <azarah@gentoo.org> (22 Dec 2002).
 107
 108         # The meaning of the 'debug' USE flag does not apply to the --with-debug
 109         # switch (enabling the libxml2 debug module). See bug #100898.
 110
 111         # --with-mem-debug causes unusual segmentation faults (bug #105120).
 112
 113         libxml2_configure() {
 114                 ECONF_SOURCE="${S}" econf \
 115                         --with-html-subdir=${PF}/html \
 116                         $(use_with debug run-debug) \
 117                         $(use_with icu) \
 118                         $(use_with lzma) \
 119                         $(use_enable ipv6) \
 120                         $(use_enable static-libs static) \
 121                         $(multilib_native_use_with readline) \
 122                         $(multilib_native_use_with readline history) \
 123                         "$@"
 124         }
 125
 126         libxml2_py_configure() {
 127                 mkdir -p "${BUILD_DIR}" || die # ensure python build dirs exist
 128                 run_in_build_dir libxml2_configure "--with-python=${ROOT%/}${PYTHON}" # odd build system, also see bug #582130
 129         }
 130
 131         libxml2_configure --without-python # build python bindings separately
 132
 133         if multilib_is_native_abi && use python; then
 134                 python_foreach_impl libxml2_py_configure
 135         fi
 136 }
 137
 138 multilib_src_compile() {
 139         default
 140         if multilib_is_native_abi && use python; then
 141                 local native_builddir=${BUILD_DIR}
 142                 python_foreach_impl libxml2_py_emake top_builddir="${native_builddir}" all
 143         fi
 144 }
 145
 146 multilib_src_test() {
 147         emake check
 148         multilib_is_native_abi && use python && python_foreach_impl libxml2_py_emake test
 149 }
 150
 151 multilib_src_install() {
 152         emake DESTDIR="${D}" \
 153                 EXAMPLES_DIR="${EPREFIX}"/usr/share/doc/${PF}/examples install
 154
 155         if multilib_is_native_abi && use python; then
 156                 python_foreach_impl libxml2_py_emake \
 157                         DESTDIR="${D}" \
 158                         docsdir="${EPREFIX}"/usr/share/doc/${PF}/python \
 159                         exampledir="${EPREFIX}"/usr/share/doc/${PF}/python/examples \
 160                         install
 161                 python_foreach_impl python_optimize
 162         fi
 163 }
 164
 165 multilib_src_install_all() {
 166         # on windows, xmllint is installed by interix libxml2 in parent prefix.
 167         # this is the version to use. the native winnt version does not support
 168         # symlinks, which makes repoman fail if the portage tree is linked in
 169         # from another location (which is my default). -- mduft
 170         if [[ ${CHOST} == *-winnt* ]]; then
 171                 rm -rf "${ED}"/usr/bin/xmllint
 172                 rm -rf "${ED}"/usr/bin/xmlcatalog
 173         fi
 174
 175         rm -rf "${ED}"/usr/share/doc/${P}
 176         einstalldocs
 177
 178         if ! use examples; then
 179                 rm -rf "${ED}"/usr/share/doc/${PF}/examples
 180                 rm -rf "${ED}"/usr/share/doc/${PF}/python/examples
 181         fi
 182
 183         prune_libtool_files --modules
 184 }
 185
 186 pkg_postinst() {
 187         # We don't want to do the xmlcatalog during stage1, as xmlcatalog will not
 188         # be in / and stage1 builds to ROOT=/tmp/stage1root. This fixes bug #208887.
 189         if [[ "${ROOT}" != "/" ]]; then
 190                 elog "Skipping XML catalog creation for stage building (bug #208887)."
 191         else
 192                 # need an XML catalog, so no-one writes to a non-existent one
 193                 CATALOG="${EROOT}etc/xml/catalog"
 194
 195                 # we dont want to clobber an existing catalog though,
 196                 # only ensure that one is there
 197                 # <obz@gentoo.org>
 198                 if [[ ! -e ${CATALOG} ]]; then
 199                         [[ -d "${EROOT}etc/xml" ]] || mkdir -p "${EROOT}etc/xml"
 200                         "${EPREFIX}"/usr/bin/xmlcatalog --create > "${CATALOG}"
 201                         einfo "Created XML catalog in ${CATALOG}"
 202                 fi
 203         fi
 204 }
 205
 206 libxml2_py_emake() {
 207         pushd "${BUILD_DIR}/python" > /dev/null || die
 208         emake "$@"
 209         popd > /dev/null
 210 }