dev-libs/libxml2/libxml2-2.9.7.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
   6 PYTHON_REQ_USE="xml"
   7
   8 inherit libtool flag-o-matic ltprune python-r1 autotools prefix multilib-minimal
   9
  10 DESCRIPTION="Version 2 of the library to manipulate XML files"
  11 HOMEPAGE="http://www.xmlsoft.org/"
  12
  13 LICENSE="MIT"
  14 SLOT="2"
  15 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="debug examples icu ipv6 lzma python readline static-libs test"
  17 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  18
  19 XSTS_HOME="http://www.w3.org/XML/2004/xml-schema-test-suite"
  20 XSTS_NAME_1="xmlschema2002-01-16"
  21 XSTS_NAME_2="xmlschema2004-01-14"
  22 XSTS_TARBALL_1="xsts-2002-01-16.tar.gz"
  23 XSTS_TARBALL_2="xsts-2004-01-14.tar.gz"
  24 XMLCONF_TARBALL="xmlts20080827.tar.gz"
  25
  26 SRC_URI="ftp://xmlsoft.org/${PN}/${PN}-${PV/_rc/-rc}.tar.gz
  27         test? (
  28                 ${XSTS_HOME}/${XSTS_NAME_1}/${XSTS_TARBALL_1}
  29                 ${XSTS_HOME}/${XSTS_NAME_2}/${XSTS_TARBALL_2}
  30                 http://www.w3.org/XML/Test/${XMLCONF_TARBALL} )"
  31
  32 RDEPEND="
  33         >=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
  34         icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
  35         lzma? ( >=app-arch/xz-utils-5.0.5-r1:=[${MULTILIB_USEDEP}] )
  36         python? ( ${PYTHON_DEPS} )
  37         readline? ( sys-libs/readline:= )
  38 "
  39 DEPEND="${RDEPEND}
  40         dev-util/gtk-doc-am
  41         virtual/pkgconfig
  42         hppa? ( >=sys-devel/binutils-2.15.92.0.2 )
  43 "
  44
  45 S="${WORKDIR}/${PN}-${PV%_rc*}"
  46
  47 MULTILIB_CHOST_TOOLS=(
  48         /usr/bin/xml2-config
  49 )
  50
  51 src_unpack() {
  52         # ${A} isn't used to avoid unpacking of test tarballs into $WORKDIR,
  53         # as they are needed as tarballs in ${S}/xstc instead and not unpacked
  54         unpack ${P/_rc/-rc}.tar.gz
  55         cd "${S}" || die
  56
  57         if use test; then
  58                 cp "${DISTDIR}/${XSTS_TARBALL_1}" \
  59                         "${DISTDIR}/${XSTS_TARBALL_2}" \
  60                         "${S}"/xstc/ \
  61                         || die "Failed to install test tarballs"
  62                 unpack ${XMLCONF_TARBALL}
  63         fi
  64 }
  65
  66 src_prepare() {
  67         default
  68
  69         DOCS=( AUTHORS ChangeLog NEWS README* TODO* )
  70
  71         # Patches needed for prefix support
  72         eapply "${FILESDIR}"/${PN}-2.7.1-catalog_path.patch
  73
  74         eprefixify catalog.c xmlcatalog.c runtest.c xmllint.c
  75
  76         # Fix build for Windows platform
  77         # https://bugzilla.gnome.org/show_bug.cgi?id=760456
  78         # eapply "${FILESDIR}"/${PN}-2.8.0_rc1-winnt.patch
  79
  80         # Fix python detection, bug #567066
  81         # https://bugzilla.gnome.org/show_bug.cgi?id=760458
  82         eapply "${FILESDIR}"/${PN}-2.9.2-python-ABIFLAG.patch
  83
  84         # Avoid final linking arguments for python modules
  85         if [[ ${CHOST} == *-darwin* ]] ; then
  86                 sed -i -e '/PYTHON_LIBS/s/ldflags/libs/' configure.ac || die
  87         fi
  88
  89         # Please do not remove, as else we get references to PORTAGE_TMPDIR
  90         # in /usr/lib/python?.?/site-packages/libxml2mod.la among things.
  91         # We now need to run eautoreconf at the end to prevent maintainer mode.
  92 #       elibtoolize
  93 #       epunt_cxx # if we don't eautoreconf
  94
  95         eautoreconf
  96 }
  97
  98 multilib_src_configure() {
  99         # filter seemingly problematic CFLAGS (#26320)
 100         filter-flags -fprefetch-loop-arrays -funroll-loops
 101
 102         # USE zlib support breaks gnome2
 103         # (libgnomeprint for instance fails to compile with
 104         # fresh install, and existing) - <azarah@gentoo.org> (22 Dec 2002).
 105
 106         # The meaning of the 'debug' USE flag does not apply to the --with-debug
 107         # switch (enabling the libxml2 debug module). See bug #100898.
 108
 109         # --with-mem-debug causes unusual segmentation faults (bug #105120).
 110
 111         libxml2_configure() {
 112                 ECONF_SOURCE="${S}" econf \
 113                         --with-html-subdir=${PF}/html \
 114                         $(use_with debug run-debug) \
 115                         $(use_with icu) \
 116                         $(use_with lzma) \
 117                         $(use_enable ipv6) \
 118                         $(use_enable static-libs static) \
 119                         $(multilib_native_use_with readline) \
 120                         $(multilib_native_use_with readline history) \
 121                         "$@"
 122         }
 123
 124         libxml2_py_configure() {
 125                 mkdir -p "${BUILD_DIR}" || die # ensure python build dirs exist
 126                 run_in_build_dir libxml2_configure "--with-python=${ROOT%/}${PYTHON}" # odd build system, also see bug #582130
 127         }
 128
 129         libxml2_configure --without-python # build python bindings separately
 130
 131         if multilib_is_native_abi && use python; then
 132                 python_foreach_impl libxml2_py_configure
 133         fi
 134 }
 135
 136 multilib_src_compile() {
 137         default
 138         if multilib_is_native_abi && use python; then
 139                 local native_builddir=${BUILD_DIR}
 140                 python_foreach_impl libxml2_py_emake top_builddir="${native_builddir}" all
 141         fi
 142 }
 143
 144 multilib_src_test() {
 145         emake check
 146         multilib_is_native_abi && use python && python_foreach_impl libxml2_py_emake test
 147 }
 148
 149 multilib_src_install() {
 150         emake DESTDIR="${D}" \
 151                 EXAMPLES_DIR="${EPREFIX}"/usr/share/doc/${PF}/examples install
 152
 153         if multilib_is_native_abi && use python; then
 154                 python_foreach_impl libxml2_py_emake \
 155                         DESTDIR="${D}" \
 156                         docsdir="${EPREFIX}"/usr/share/doc/${PF}/python \
 157                         exampledir="${EPREFIX}"/usr/share/doc/${PF}/python/examples \
 158                         install
 159                 python_foreach_impl python_optimize
 160         fi
 161 }
 162
 163 multilib_src_install_all() {
 164         # on windows, xmllint is installed by interix libxml2 in parent prefix.
 165         # this is the version to use. the native winnt version does not support
 166         # symlinks, which makes repoman fail if the portage tree is linked in
 167         # from another location (which is my default). -- mduft
 168         if [[ ${CHOST} == *-winnt* ]]; then
 169                 rm -rf "${ED}"/usr/bin/xmllint
 170                 rm -rf "${ED}"/usr/bin/xmlcatalog
 171         fi
 172
 173         rm -rf "${ED}"/usr/share/doc/${P}
 174         einstalldocs
 175
 176         if ! use examples; then
 177                 rm -rf "${ED}"/usr/share/doc/${PF}/examples
 178                 rm -rf "${ED}"/usr/share/doc/${PF}/python/examples
 179         fi
 180
 181         prune_libtool_files --modules
 182 }
 183
 184 pkg_postinst() {
 185         # We don't want to do the xmlcatalog during stage1, as xmlcatalog will not
 186         # be in / and stage1 builds to ROOT=/tmp/stage1root. This fixes bug #208887.
 187         if [[ "${ROOT}" != "/" ]]; then
 188                 elog "Skipping XML catalog creation for stage building (bug #208887)."
 189         else
 190                 # need an XML catalog, so no-one writes to a non-existent one
 191                 CATALOG="${EROOT}etc/xml/catalog"
 192
 193                 # we dont want to clobber an existing catalog though,
 194                 # only ensure that one is there
 195                 # <obz@gentoo.org>
 196                 if [[ ! -e ${CATALOG} ]]; then
 197                         [[ -d "${EROOT}etc/xml" ]] || mkdir -p "${EROOT}etc/xml"
 198                         "${EPREFIX}"/usr/bin/xmlcatalog --create > "${CATALOG}"
 199                         einfo "Created XML catalog in ${CATALOG}"
 200                 fi
 201         fi
 202 }
 203
 204 libxml2_py_emake() {
 205         pushd "${BUILD_DIR}/python" > /dev/null || die
 206         emake "$@"
 207         popd > /dev/null
 208 }