dev-libs/libwacom/libwacom-1.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit meson udev toolchain-funcs
   7
   8 DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
   9 HOMEPAGE="https://github.com/linuxwacom/libwacom"
  10 SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.bz2"
  11
  12 LICENSE="MIT"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 sparc ~x86"
  15 IUSE="doc test"
  16 RESTRICT="!test? ( test )"
  17
  18 BDEPEND="
  19         virtual/pkgconfig
  20         doc? ( app-doc/doxygen )
  21 "
  22 RDEPEND="
  23         dev-libs/glib:2
  24         dev-libs/libgudev:=
  25 "
  26 DEPEND="${RDEPEND}"
  27
  28 PATCHES=(
  29         "${FILESDIR}/${P}-meson-add-private.patch"
  30         "${FILESDIR}/${P}-match-with-autotools.patch"
  31         "${FILESDIR}/${P}-configurable_docs.patch"
  32 )
  33
  34 pkg_setup() {
  35         tc-ld-disable-gold # bug https://github.com/linuxwacom/libwacom/issues/170
  36 }
  37
  38 src_configure() {
  39         local emesonargs=(
  40                 $(meson_feature doc documentation)
  41                 $(meson_use test tests)
  42                 -Dudev-dir=$(get_udevdir)
  43
  44         )
  45         meson_src_configure
  46 }