dev-libs/libverto/libverto-0.3.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools multilib-minimal
   7
   8 DESCRIPTION="Main event loop abstraction library"
   9 HOMEPAGE="https://github.com/latchset/libverto/"
  10 SRC_URI="https://github.com/latchset/libverto/releases/download/${PV}/${P}.tar.gz"
  11
  12 LICENSE="MIT"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
  15 IUSE="glib +libev libevent tevent +threads static-libs"
  16
  17 DEPEND="glib? ( >=dev-libs/glib-2.34.3[${MULTILIB_USEDEP}] )
  18         libev? ( >=dev-libs/libev-4.15[${MULTILIB_USEDEP}] )
  19         libevent? ( >=dev-libs/libevent-2.0.21[${MULTILIB_USEDEP}] )
  20         tevent? ( >=sys-libs/tevent-0.9.19[${MULTILIB_USEDEP}] )"
  21
  22 RDEPEND="${DEPEND}"
  23
  24 REQUIRED_USE="|| ( glib libev libevent tevent ) "
  25
  26 DOCS=( AUTHORS ChangeLog NEWS INSTALL README )
  27
  28 src_prepare() {
  29         default
  30         # known problem uptream with tevent write test.  tevent does not fire a
  31         # callback on error, but we explicitly test for this behaviour.  Do not run
  32         # tevent tests for now.
  33         sed -i -e 's/def HAVE_TEVENT/ 0/' tests/test.h || die
  34         eautoreconf
  35 }
  36
  37 multilib_src_configure() {
  38         ECONF_SOURCE="${S}" \
  39         econf \
  40                 $(use_with glib) \
  41                 $(use_with libev) \
  42                 $(use_with libevent) \
  43                 $(use_with tevent) \
  44                 $(use_with threads pthread) \
  45                 $(use_enable static-libs static)
  46 }
  47
  48 multilib_src_install_all() {
  49         default
  50         use static-libs || find "${ED}" -name '*.la' -delete
  51 }