dev-libs/libuv/libuv-1.37.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit autotools multilib-minimal
   6
   7 DESCRIPTION="Cross-platform asychronous I/O"
   8 HOMEPAGE="https://github.com/libuv/libuv"
   9 SRC_URI="https://github.com/libuv/libuv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="BSD BSD-2 ISC MIT"
  12 SLOT="0/1"
  13 KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  14 IUSE="static-libs"
  15 RESTRICT="test"
  16
  17 DEPEND="sys-devel/libtool
  18         virtual/pkgconfig[${MULTILIB_USEDEP}]"
  19
  20 src_prepare() {
  21         default
  22
  23         echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
  24                 > m4/libuv-extra-automake-flags.m4 || die
  25
  26         # upstream fails to ship a configure script
  27         eautoreconf
  28 }
  29
  30 multilib_src_configure() {
  31         local myeconfargs=(
  32                 cc_cv_cflags__g=no
  33                 $(use_enable static-libs static)
  34         )
  35         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  36 }
  37
  38 multilib_src_test() {
  39         mkdir "${BUILD_DIR}"/test || die
  40         cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
  41         default
  42 }
  43
  44 multilib_src_install_all() {
  45         einstalldocs
  46         find "${D}" -name '*.la' -delete || die
  47 }