dev-libs/libtasn1/libtasn1-4.13.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit multilib-minimal libtool
   7
   8 DESCRIPTION="ASN.1 library"
   9 HOMEPAGE="https://www.gnu.org/software/libtasn1/"
  10 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3 LGPL-2.1"
  13 SLOT="0/6" # subslot = libtasn1 soname version
  14 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~riscv s390 ~sh sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="doc static-libs test valgrind"
  16
  17 RESTRICT="!test? ( test )"
  18
  19 BDEPEND="sys-apps/help2man
  20         virtual/yacc
  21         test? ( valgrind? ( dev-util/valgrind ) )"
  22
  23 DOCS=(
  24         AUTHORS
  25         ChangeLog
  26         NEWS
  27         README
  28         THANKS
  29 )
  30
  31 pkg_setup() {
  32         if use doc; then
  33                 DOCS+=( doc/libtasn1.pdf )
  34                 HTML_DOCS=( doc/reference/html/. )
  35         fi
  36 }
  37
  38 src_prepare() {
  39         default
  40         elibtoolize  # for Solaris shared library
  41 }
  42
  43 multilib_src_configure() {
  44         ECONF_SOURCE="${S}" econf \
  45                 $(use_enable static-libs static) \
  46                 $(multilib_native_use_enable valgrind valgrind-tests)
  47 }
  48
  49 multilib_src_install_all() {
  50         einstalldocs
  51         find "${D}" -name '*.la' -delete || die
  52 }