dev-libs/libslz/libslz-1.1.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs multilib-minimal
   6
   7 DESCRIPTION="stateless, zlib-compatible, and very fast compression library"
   8 HOMEPAGE="http://1wt.eu/projects/libslz"
   9 SRC_URI="http://git.1wt.eu/web?p=${PN}.git;a=snapshot;h=v${PV};sf=tbz2 -> ${P}.tar.bz2"
  10
  11 LICENSE="MIT"
  12 SLOT="0/1"
  13 KEYWORDS="amd64 arm ppc x86"
  14 IUSE="static-libs tools"
  15
  16 DEPEND=""
  17 RDEPEND="${DEPEND}"
  18
  19 S="${WORKDIR}/${PN}"
  20
  21 src_prepare() {
  22         default
  23
  24         multilib_copy_sources
  25 }
  26
  27 multilib_src_compile() {
  28         local -a opts=(
  29                 CC="$(tc-getCC)" \
  30                 OPT_CFLAGS="${CFLAGS}" \
  31                 USR_LFLAGS="${LDFLAGS}" \
  32                 shared \
  33                 $(usex static-libs static '')
  34         )
  35
  36         if multilib_is_native_abi ; then
  37                 opts+=(
  38                         $(usex tools tools '')
  39                 )
  40         fi
  41
  42         emake "${opts[@]}"
  43 }
  44
  45 multilib_src_install() {
  46         local -a opts=(
  47                 STRIP=":" \
  48                 DESTDIR="${ED}" \
  49                 PREFIX="${EPREFIX}/usr" \
  50                 LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
  51                 install-headers
  52                 install-shared \
  53                 $(usex static-libs install-static '')
  54         )
  55
  56         if multilib_is_native_abi ; then
  57                 einstalldocs
  58
  59                 opts+=(
  60                         $(usex tools install-tools '')
  61                 )
  62         fi
  63
  64         emake "${opts[@]}"
  65 }