dev-libs/librevenge/librevenge-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic multilib-minimal
   7
   8 if [[ ${PV} == *9999 ]] ; then
   9         EGIT_REPO_URI="git://git.code.sf.net/p/libwpd/librevenge"
  10         inherit git-r3 autotools
  11 else
  12         SRC_URI="https://sf.net/projects/libwpd/files/${PN}/${P}/${P}.tar.xz"
  13         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
  14 fi
  15 DESCRIPTION="Helper library for REVerse ENGineered formats filters"
  16 HOMEPAGE="https://sf.net/p/libwpd/librevenge"
  17
  18 LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
  19 SLOT="0"
  20 IUSE="doc test"
  21 RESTRICT="!test? ( test )"
  22
  23 BDEPEND="
  24         doc? ( app-doc/doxygen )
  25 "
  26 RDEPEND="
  27         sys-libs/zlib[${MULTILIB_USEDEP}]
  28 "
  29 DEPEND="${RDEPEND}
  30         dev-libs/boost
  31         test? ( dev-util/cppunit[${MULTILIB_USEDEP}] )
  32 "
  33
  34 src_prepare() {
  35         default
  36         [[ ${PV} = *9999 ]] && eautoreconf
  37
  38         # bug 651264
  39         append-cxxflags -std=c++11
  40 }
  41
  42 multilib_src_configure() {
  43         local myeconfargs=(
  44                 --disable-static
  45                 --disable-werror
  46                 $(use_with doc docs)
  47                 $(use_enable test tests)
  48         )
  49         ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
  50 }
  51
  52 multilib_src_install_all() {
  53         einstalldocs
  54         find "${D}" -name '*.la' -type f -delete || die
  55 }