dev-libs/librevenge/librevenge-0.0.4-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit multilib-minimal
   7
   8 DESCRIPTION="A helper library for REVerse ENGineered formats filters"
   9 HOMEPAGE="http://sf.net/p/libwpd/librevenge"
  10 if [[ ${PV} == *9999 ]] ; then
  11         EGIT_REPO_URI="git://git.code.sf.net/p/libwpd/librevenge"
  12         inherit git-r3 autotools
  13 else
  14         SRC_URI="http://sf.net/projects/libwpd/files/${PN}/${P}/${P}.tar.xz"
  15         KEYWORDS="~alpha amd64 ~arm ~arm64 hppa ~ia64 ~mips ppc ppc64 x86 ~x86-fbsd"
  16 fi
  17
  18 LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
  19 SLOT="0"
  20 IUSE="doc test"
  21
  22 RDEPEND="
  23         sys-libs/zlib[${MULTILIB_USEDEP}]
  24 "
  25 DEPEND="${RDEPEND}
  26         dev-libs/boost
  27         doc? ( app-doc/doxygen )
  28         test? ( dev-util/cppunit[${MULTILIB_USEDEP}] )
  29 "
  30
  31 src_prepare() {
  32         default
  33         [[ ${PV} = *9999 ]] && eautoreconf
  34 }
  35
  36 multilib_src_configure() {
  37         ECONF_SOURCE=${S} \
  38         econf \
  39                 --disable-static \
  40                 --disable-werror \
  41                 $(use_with doc docs) \
  42                 $(use_enable test tests)
  43 }
  44
  45 multilib_src_install_all() {
  46         einstalldocs
  47         find "${D}" -name '*.la' -delete || die
  48 }