dev-libs/libressl/libressl-2.8.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit multilib-minimal
   7
   8 DESCRIPTION="Free version of the SSL/TLS protocol forked from OpenSSL"
   9 HOMEPAGE="https://www.libressl.org/"
  10 SRC_URI="https://ftp.openbsd.org/pub/OpenBSD/LibreSSL/${P}.tar.gz"
  11
  12 LICENSE="ISC openssl"
  13 # Reflects ABI of libcrypto.so and libssl.so.  Since these can differ,
  14 # we'll try to use the max of either.  However, if either change between
  15 # versions, we have to change the subslot to trigger rebuild of consumers.
  16 SLOT="0/46"
  17 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
  18 IUSE="+asm static-libs test"
  19 REQUIRED_USE="test? ( static-libs )"
  20
  21 RDEPEND="!dev-libs/openssl:0"
  22 DEPEND="${RDEPEND}"
  23 PDEPEND="app-misc/ca-certificates"
  24
  25 src_prepare() {
  26         touch crypto/Makefile.in
  27
  28         sed -i \
  29                 -e '/^[ \t]*CFLAGS=/s#-g ##' \
  30                 -e '/^[ \t]*CFLAGS=/s#-g"#"#' \
  31                 -e '/^[ \t]*CFLAGS=/s#-O2 ##' \
  32                 -e '/^[ \t]*CFLAGS=/s#-O2"#"#' \
  33                 -e '/^[ \t]*USER_CFLAGS=/s#-O2 ##' \
  34                 -e '/^[ \t]*USER_CFLAGS=/s#-O2"#"#' \
  35                 configure || die "fixing CFLAGS failed"
  36
  37         eapply_user
  38 }
  39
  40 multilib_src_configure() {
  41         ECONF_SOURCE="${S}" econf \
  42                 $(use_enable asm) \
  43                 $(use_enable static-libs static)
  44 }
  45
  46 multilib_src_test() {
  47         emake check
  48 }
  49
  50 multilib_src_install_all() {
  51         einstalldocs
  52         find "${D}" -name '*.la' -exec rm -f {} + || die
  53 }