dev-libs/librelp/librelp-1.2.15.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit autotools
   7
   8 DESCRIPTION="An easy to use library for the RELP protocol"
   9 HOMEPAGE="http://www.librelp.com/"
  10 SRC_URI="http://download.rsyslog.com/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3+ doc? ( FDL-1.3 )"
  13
  14 # subslot = soname version
  15 SLOT="0/0.3.0"
  16
  17 KEYWORDS="amd64 arm arm64 hppa sparc x86"
  18 IUSE="debug doc +ssl static-libs"
  19
  20 RDEPEND="
  21         ssl? ( >=net-libs/gnutls-3.3.17.1:0= )
  22 "
  23
  24 DEPEND="
  25         ssl? ( >=net-libs/gnutls-3.3.17.1:0= )
  26         virtual/pkgconfig
  27 "
  28
  29 src_prepare() {
  30         sed -i \
  31                 -e 's/ -g"/"/g' \
  32                 configure.ac || die "sed failed"
  33
  34         default
  35
  36         eautoreconf
  37 }
  38
  39 src_configure() {
  40         local myeconfargs=(
  41                 $(use_enable debug)
  42                 $(use_enable ssl tls)
  43                 $(use_enable static-libs static)
  44         )
  45
  46         econf "${myeconfargs[@]}"
  47 }
  48
  49 src_install() {
  50         local DOCS=( ChangeLog )
  51         use doc && local HTML_DOCS=( doc/relp.html )
  52         default
  53
  54         find "${ED}"usr/lib* -name '*.la' -delete || die
  55 }