dev-libs/liborcus/liborcus-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 inherit python-single-r1
   8
   9 DESCRIPTION="Standalone file import filter library for spreadsheet documents"
  10 HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
  11
  12 if [[ ${PV} == *9999* ]]; then
  13         MDDS_SLOT="1/9999"
  14         EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
  15         inherit git-r3 autotools
  16 else
  17         MDDS_SLOT="1/1.5"
  18         SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
  19         KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
  20 fi
  21
  22 LICENSE="MIT"
  23 SLOT="0/0.16" # based on SONAME of liborcus.so
  24 IUSE="python +spreadsheet-model tools"
  25
  26 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  27
  28 RDEPEND="
  29         dev-libs/boost:=[zlib(+)]
  30         sys-libs/zlib
  31         python? ( ${PYTHON_DEPS} )
  32         spreadsheet-model? ( dev-libs/libixion:${SLOT} )
  33 "
  34 DEPEND="${RDEPEND}
  35         dev-util/mdds:${MDDS_SLOT}
  36 "
  37
  38 pkg_setup() {
  39         use python && python-single-r1_pkg_setup
  40 }
  41
  42 src_prepare() {
  43         default
  44         [[ ${PV} == *9999 ]] && eautoreconf
  45 }
  46
  47 src_configure() {
  48         local myeconfargs=(
  49                 --disable-static
  50                 --disable-werror
  51                 $(use_enable python)
  52                 $(use_enable spreadsheet-model)
  53                 $(use_with tools)
  54         )
  55         econf "${myeconfargs[@]}"
  56 }
  57
  58 src_install() {
  59         default
  60         find "${D}" -name '*.la' -type f -delete || die
  61 }