dev-libs/liborcus/liborcus-0.15.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 inherit autotools python-single-r1
   8
   9 DESCRIPTION="Standalone file import filter library for spreadsheet documents"
  10 HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
  11
  12 if [[ ${PV} == *9999* ]]; then
  13         EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
  14         inherit git-r3
  15 else
  16         SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
  17         KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 ~x86"
  18 fi
  19
  20 LICENSE="MIT"
  21 SLOT="0/0.15" # based on SONAME of liborcus.so
  22 IUSE="python +spreadsheet-model tools"
  23
  24 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  25
  26 RDEPEND="
  27         dev-libs/boost:=[zlib(+)]
  28         sys-libs/zlib
  29         python? ( ${PYTHON_DEPS} )
  30         spreadsheet-model? ( dev-libs/libixion:${SLOT} )
  31 "
  32 DEPEND="${RDEPEND}
  33         dev-util/mdds:1/1.5
  34 "
  35
  36 PATCHES=( "${FILESDIR}/${P}-bashism.patch" ) # bug 723130
  37
  38 pkg_setup() {
  39         use python && python-single-r1_pkg_setup
  40 }
  41
  42 src_prepare() {
  43         default
  44         eautoreconf
  45 }
  46
  47 src_configure() {
  48         local myeconfargs=(
  49                 --disable-static
  50                 --disable-werror
  51                 $(use_enable python)
  52                 $(use_enable spreadsheet-model)
  53                 $(use_with tools)
  54         )
  55         econf "${myeconfargs[@]}"
  56 }
  57
  58 src_install() {
  59         default
  60         find "${D}" -name '*.la' -type f -delete || die
  61 }