dev-libs/liborcus/liborcus-0.14.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
   7
   8 PYTHON_COMPAT=( python{3_4,3_5,3_6} )
   9
  10 [[ ${PV} == 9999 ]] && GITECLASS="git-r3 autotools"
  11 inherit python-single-r1 ${GITECLASS}
  12 unset GITECLASS
  13
  14 DESCRIPTION="Standalone file import filter library for spreadsheet documents"
  15 HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
  16 [[ ${PV} == 9999 ]] || SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
  17
  18 LICENSE="MIT"
  19 SLOT="0/0.14" # based on SONAME of liborcus.so
  20 [[ ${PV} == 9999 ]] || \
  21 KEYWORDS=""
  22 # KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
  23 IUSE="python +spreadsheet-model static-libs tools"
  24
  25 RDEPEND="
  26         dev-libs/boost:=
  27         sys-libs/zlib
  28         python? ( ${PYTHON_DEPS} )
  29         spreadsheet-model? ( >=dev-libs/libixion-0.14.0:= )
  30 "
  31 DEPEND="${RDEPEND}
  32         >=dev-util/mdds-1.4.1:1
  33 "
  34
  35 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  36
  37 pkg_setup() {
  38         use python && python-single-r1_pkg_setup
  39 }
  40
  41 src_prepare() {
  42         default
  43         [[ ${PV} == 9999 ]] && eautoreconf
  44 }
  45
  46 src_configure() {
  47         econf \
  48                 --disable-werror \
  49                 $(use_enable python) \
  50                 $(use_enable spreadsheet-model) \
  51                 $(use_enable static-libs static) \
  52                 $(use_with tools)
  53 }
  54
  55 src_install() {
  56         default
  57         find "${D}" -name '*.la' -delete || die
  58 }