dev-libs/libnl/libnl-1.1.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils multilib toolchain-funcs
   7
   8 DESCRIPTION="Libraries providing APIs to netlink protocol based Linux kernel interfaces"
   9 HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
  10 SRC_URI="http://www.infradead.org/~tgr/libnl/files/${P}.tar.gz"
  11 LICENSE="LGPL-2.1"
  12 SLOT="1.1"
  13 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~ia64-linux ~x86-linux"
  14 IUSE="doc static-libs"
  15
  16 DEPEND="doc? ( app-doc/doxygen )"
  17 DOCS=( ChangeLog )
  18
  19 src_prepare() {
  20         epatch \
  21                 "${FILESDIR}"/${PN}-1.1-vlan-header.patch \
  22                 "${FILESDIR}"/${PN}-1.1-flags.patch \
  23                 "${FILESDIR}"/${PN}-1.1.3-offsetof.patch
  24         sed -i \
  25                 -e '/@echo/d' \
  26                 Makefile.rules {lib,src,tests}/Makefile || die
  27         sed -i \
  28                 -e 's|-g ||g' \
  29                 Makefile.opts.in || die
  30
  31         if ! use static-libs; then
  32                 sed -i lib/Makefile -e '/OUT_AR/d' || die
  33         fi
  34
  35         rm -f lib/libnl.a
  36 }
  37
  38 src_compile() {
  39         emake AR=$(tc-getAR)
  40
  41         if use doc ; then
  42                 cd "${S}/doc"
  43                 emake gendoc || die
  44         fi
  45 }
  46
  47 src_install() {
  48         default
  49
  50         if use doc ; then
  51                 cd "${S}/doc"
  52                 dohtml -r html/*
  53         fi
  54 }