dev-libs/libnl/libnl-1.1.4-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit multilib toolchain-funcs
   6
   7 DESCRIPTION="Libraries providing APIs to netlink protocol based Linux kernel interfaces"
   8 HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
   9 SRC_URI="http://www.infradead.org/~tgr/libnl/files/${P}.tar.gz"
  10 LICENSE="LGPL-2.1"
  11 SLOT="1.1"
  12 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
  13 IUSE="doc static-libs"
  14
  15 DEPEND="doc? ( app-doc/doxygen )"
  16 DOCS=( ChangeLog )
  17 PATCHES=(
  18         "${FILESDIR}"/${PN}-1.1-vlan-header.patch
  19         "${FILESDIR}"/${PN}-1.1-flags.patch
  20         "${FILESDIR}"/${PN}-1.1.3-offsetof.patch
  21 )
  22
  23 src_prepare() {
  24         default
  25
  26         sed -i \
  27                 -e '/@echo/d' \
  28                 Makefile.rules {lib,src,tests}/Makefile || die
  29         sed -i \
  30                 -e 's|-g ||g' \
  31                 Makefile.opts.in || die
  32
  33         if ! use static-libs; then
  34                 sed -i lib/Makefile -e '/OUT_AR/d' || die
  35         fi
  36
  37         rm -f lib/libnl.a
  38 }
  39
  40 src_compile() {
  41         emake AR=$(tc-getAR)
  42
  43         if use doc ; then
  44                 cd "${S}/doc"
  45                 emake gendoc
  46         fi
  47 }
  48
  49 src_install() {
  50         default
  51
  52         if use doc ; then
  53                 cd "${S}/doc"
  54                 docinto html
  55                 dodoc -r html/*
  56         fi
  57 }