dev-libs/libixion/libixion-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{5,6,7} )
   7 inherit python-single-r1
   8
   9 DESCRIPTION="General purpose formula parser & interpreter"
  10 HOMEPAGE="https://gitlab.com/ixion/ixion"
  11
  12 if [[ ${PV} == 9999 ]]; then
  13         EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
  14         inherit git-r3 autotools
  15 else
  16         SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
  17         KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
  18 fi
  19
  20 LICENSE="MIT"
  21 SLOT="0/0.15" # based on SONAME of libixion.so
  22 IUSE="debug python static-libs +threads"
  23
  24 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  25
  26 RDEPEND="
  27         dev-libs/boost:=
  28         >=dev-util/mdds-1.5.0:1=
  29         python? ( ${PYTHON_DEPS} )
  30 "
  31 DEPEND="${RDEPEND}
  32         dev-libs/spdlog
  33 "
  34
  35 PATCHES=( "${FILESDIR}"/${P}-spdlog-non-bundled-fmt.patch )
  36
  37 pkg_setup() {
  38         use python && python-single-r1_pkg_setup
  39 }
  40
  41 src_prepare() {
  42         default
  43         [[ ${PV} == 9999 ]] && eautoreconf
  44 }
  45
  46 src_configure() {
  47         econf \
  48                 $(use_enable debug) \
  49                 $(use_enable python) \
  50                 $(use_enable static-libs static) \
  51                 $(use_enable threads)
  52 }
  53
  54 src_install() {
  55         default
  56         find "${D}" -name '*.la' -delete || die
  57 }