dev-libs/libixion/libixion-0.9.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
   8
   9 PYTHON_COMPAT=( python2_7 )
  10
  11 [[ ${PV} == 9999 ]] && GITECLASS="git-r3"
  12 inherit autotools eutils python-single-r1 ${GITECLASS}
  13 unset GITECLASS
  14
  15 DESCRIPTION="General purpose formula parser & interpreter"
  16 HOMEPAGE="https://gitlab.com/ixion/ixion"
  17 [[ ${PV} == 9999 ]] || SRC_URI="http://kohei.us/files/ixion/src/${P}.tar.xz"
  18
  19 LICENSE="MIT"
  20 SLOT="0/0.10"
  21 [[ ${PV} == 9999 ]] || \
  22 KEYWORDS="~amd64 ~arm ~ppc ~x86"
  23 IUSE="python static-libs"
  24
  25 RDEPEND="
  26         dev-libs/boost:=[threads]
  27         python? ( ${PYTHON_DEPS} )
  28 "
  29 DEPEND="${RDEPEND}
  30         >=dev-util/mdds-0.12.0:=
  31 "
  32
  33 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  34
  35 pkg_setup() {
  36         use python && python-single-r1_pkg_setup
  37 }
  38
  39 src_prepare() {
  40         epatch "${FILESDIR}/${PN}-0.9.1-typo.patch"
  41         epatch "${FILESDIR}/${PN}-0.9.1-python-optional.patch"
  42         eautoreconf
  43 }
  44
  45 src_configure() {
  46         econf \
  47                 $(use_enable python) \
  48                 $(use_enable static-libs static)
  49 }
  50
  51 src_install() {
  52         default
  53
  54         prune_libtool_files --all
  55 }