dev-libs/libixion/libixion-0.14.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 inherit python-single-r1
   8
   9 DESCRIPTION="General purpose formula parser & interpreter"
  10 HOMEPAGE="https://gitlab.com/ixion/ixion"
  11
  12 if [[ ${PV} == 9999 ]]; then
  13         EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
  14         inherit git-r3 autotools
  15 else
  16         SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
  17         KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 x86"
  18 fi
  19
  20 LICENSE="MIT"
  21 SLOT="0/0.14" # based on SONAME of libixion.so
  22 IUSE="debug python static-libs +threads"
  23
  24 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  25
  26 DEPEND="
  27         dev-libs/boost:=
  28         =dev-util/mdds-1.4*:1
  29         python? ( ${PYTHON_DEPS} )
  30 "
  31 RDEPEND="${DEPEND}"
  32
  33 pkg_setup() {
  34         use python && python-single-r1_pkg_setup
  35 }
  36
  37 src_prepare() {
  38         default
  39         [[ ${PV} == 9999 ]] && eautoreconf
  40 }
  41
  42 src_configure() {
  43         econf \
  44                 $(use_enable debug) \
  45                 $(use_enable python) \
  46                 $(use_enable static-libs static) \
  47                 $(use_enable threads)
  48 }
  49
  50 src_install() {
  51         default
  52         find "${D}" -name '*.la' -type f -delete || die
  53 }