dev-libs/libixion/libixion-0.12.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
   7
   8 PYTHON_COMPAT=( python{3_4,3_5,3_6} )
   9
  10 [[ ${PV} == 9999 ]] && GITECLASS="git-r3 autotools"
  11 inherit eutils python-single-r1 ${GITECLASS}
  12 unset GITECLASS
  13
  14 DESCRIPTION="General purpose formula parser & interpreter"
  15 HOMEPAGE="https://gitlab.com/ixion/ixion"
  16 [[ ${PV} == 9999 ]] || SRC_URI="http://kohei.us/files/ixion/src/${P}.tar.xz"
  17
  18 LICENSE="MIT"
  19 SLOT="0/0.12" # based on SONAME of libixion.so
  20 [[ ${PV} == 9999 ]] || \
  21 KEYWORDS="amd64 ~arm ~arm64 ~ppc x86"
  22 IUSE="debug python static-libs +threads"
  23
  24 RDEPEND="
  25         dev-libs/boost:=
  26         python? ( ${PYTHON_DEPS} )
  27 "
  28 DEPEND="${RDEPEND}
  29         >=dev-util/mdds-1.2.0:1=
  30 "
  31
  32 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  33
  34 pkg_setup() {
  35         use python && python-single-r1_pkg_setup
  36 }
  37
  38 src_prepare() {
  39         default
  40         [[ ${PV} == 9999 ]] && eautoreconf
  41 }
  42
  43 src_configure() {
  44         econf \
  45                 $(use_enable debug) \
  46                 $(use_enable python) \
  47                 $(use_enable static-libs static) \
  48                 $(use_enable threads)
  49 }
  50
  51 src_install() {
  52         default
  53
  54         prune_libtool_files --all
  55 }