dev-libs/libisoburn/libisoburn-1.5.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Creation/expansion of ISO-9660 filesystems on CD/DVD media supported by libburn"
   7 HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wikis/home"
   8 SRC_URI="http://files.libburnia-project.org/releases/${P}.tar.gz"
   9
  10 LICENSE="GPL-2 GPL-3"
  11 SLOT="0"
  12 KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ppc ppc64 sparc x86"
  13 IUSE="acl debug external-filters external-filters-setuid frontend-optional
  14         launch-frontend launch-frontend-setuid libedit readline static-libs xattr zlib"
  15
  16 REQUIRED_USE="frontend-optional? ( || ( launch-frontend launch-frontend-setuid ) )"
  17
  18 BDEPEND="
  19         virtual/pkgconfig
  20 "
  21 RDEPEND="
  22         >=dev-libs/libburn-1.5.2
  23         >=dev-libs/libisofs-1.5.2
  24         readline? ( sys-libs/readline:0= )
  25         !readline? ( libedit? ( dev-libs/libedit ) )
  26         acl? ( virtual/acl )
  27         xattr? ( sys-apps/attr )
  28         zlib? ( sys-libs/zlib )
  29         launch-frontend? ( dev-lang/tcl:0 dev-lang/tk:0 )
  30         launch-frontend-setuid? ( dev-lang/tcl:0 dev-lang/tk:0 )
  31         frontend-optional? ( dev-tcltk/bwidget )
  32 "
  33 DEPEND="
  34         ${RDEPEND}
  35 "
  36
  37 src_configure() {
  38         econf \
  39         $(use_enable static-libs static) \
  40         $(use_enable readline libreadline) \
  41         $(usex readline --disable-libedit $(use_enable libedit)) \
  42         $(use_enable acl libacl) \
  43         $(use_enable xattr) \
  44         $(use_enable zlib) \
  45         --disable-libjte \
  46         $(use_enable external-filters) \
  47         $(use_enable external-filters-setuid) \
  48         $(use_enable launch-frontend) \
  49         $(use_enable launch-frontend-setuid) \
  50         --disable-ldconfig-at-install \
  51         --enable-pkg-check-modules \
  52         $(use_enable debug)
  53 }
  54
  55 src_install() {
  56         default
  57
  58         dodoc CONTRIBUTORS doc/{comments,*.wiki,startup_file.txt}
  59
  60         docinto frontend
  61         dodoc frontend/README-tcltk
  62         docinto xorriso
  63         dodoc xorriso/{changelog.txt,README_gnu_xorriso}
  64
  65         find "${D}" -name '*.la' -delete || die
  66 }