dev-libs/libindicator/libindicator-12.10.1-r301.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit autotools eutils flag-o-matic virtualx multilib-minimal
   7
   8 DESCRIPTION="A set of symbols and convience functions that all indicators would like to use"
   9 HOMEPAGE="https://launchpad.net/libindicator"
  10 SRC_URI="https://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
  11
  12 LICENSE="GPL-3"
  13 SLOT="3"
  14 KEYWORDS="~amd64 ~arm ~x86"
  15 IUSE="test"
  16
  17 RDEPEND=">=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
  18         >=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP}]"
  19 DEPEND="${RDEPEND}
  20         virtual/pkgconfig[${MULTILIB_USEDEP}]
  21         test? ( dev-util/dbus-test-runner )"
  22
  23 src_prepare() {
  24         # https://bugs.launchpad.net/libindicator/+bug/1502925
  25         epatch "${FILESDIR}"/${PN}-ldflags-spacing.patch
  26         eautoreconf
  27 }
  28
  29 multilib_src_configure() {
  30         append-flags -Wno-error
  31
  32         myconf=(
  33                 --disable-silent-rules
  34                 --disable-static
  35                 --with-gtk=3
  36         )
  37         local ECONF_SOURCE=${S}
  38         econf "${myconf[@]}"
  39 }
  40
  41 multilib_src_test() {
  42         Xemake check #391179
  43 }
  44
  45 multilib_src_install() {
  46         emake -j1 DESTDIR="${D}" install
  47 }
  48
  49 multilib_src_install_all() {
  50         einstalldocs
  51         prune_libtool_files --all
  52 }