dev-libs/libindicate/libindicate-12.10.1-r2.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 VALA_MIN_API_VERSION="0.16"
   7 VALA_USE_DEPEND="vapigen"
   8
   9 inherit autotools eutils flag-o-matic vala
  10
  11 DESCRIPTION="A library to raise flags on DBus for other components of the desktop to pick up and visualize"
  12 HOMEPAGE="https://launchpad.net/libindicate"
  13 SRC_URI="https://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
  14
  15 LICENSE="LGPL-2.1 LGPL-3"
  16 SLOT="3"
  17 KEYWORDS="~alpha amd64 ~arm hppa ~mips ppc ~ppc64 ~sparc ~x86"
  18 IUSE="gtk +introspection"
  19
  20 RESTRICT="test" # consequence of the -no-mono.patch
  21
  22 RDEPEND=">=dev-libs/dbus-glib-0.100
  23         >=dev-libs/glib-2.30
  24         >=dev-libs/libdbusmenu-0.6.2[introspection?]
  25         dev-libs/libxml2
  26         gtk? (
  27                 dev-libs/libdbusmenu[gtk3]
  28                 >=x11-libs/gtk+-3.2:3
  29         )
  30         introspection? ( >=dev-libs/gobject-introspection-1 )
  31         !<${CATEGORY}/${PN}-0.6.1-r201"
  32 EAUTORECONF_DEPEND="dev-util/gtk-doc-am
  33         gnome-base/gnome-common"
  34 DEPEND="${RDEPEND}
  35         ${EAUTORECONF_DEPEND}
  36         $(vala_depend)
  37         app-text/gnome-doc-utils
  38         virtual/pkgconfig"
  39
  40 src_prepare() {
  41         vala_src_prepare
  42
  43         epatch "${FILESDIR}"/${PN}-0.6.1-no-mono.patch
  44
  45         sed -i \
  46                 -e "s:vapigen:vapigen-$(vala_best_api_version):" \
  47                 -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" \
  48                 configure.ac || die
  49
  50         eautoreconf
  51 }
  52
  53 src_configure() {
  54         append-flags -Wno-error
  55
  56         # python bindings are only for GTK+-2.x
  57         econf \
  58                 --disable-silent-rules \
  59                 --disable-static \
  60                 $(use_enable gtk) \
  61                 $(use_enable introspection) \
  62                 --disable-python \
  63                 --disable-scrollkeeper \
  64                 --with-gtk=3
  65 }
  66
  67 src_install() {
  68         # work around failing parallel installation (-j1)
  69         # until a better fix is available. (bug #469032)
  70         emake -j1 DESTDIR="${D}" install
  71         dodoc AUTHORS ChangeLog NEWS
  72
  73         prune_libtool_files
  74 }