dev-libs/libical/libical-3.0.6.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{5,6,7} )
   7 VALA_USE_DEPEND="vapigen"
   8 inherit cmake-utils python-any-r1 vala
   9
  10 DESCRIPTION="An implementation of basic iCAL protocols"
  11 HOMEPAGE="https://github.com/libical/libical"
  12 SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
  13
  14 LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
  15 SLOT="0/3"
  16 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  17 IUSE="berkdb doc examples introspection static-libs test vala"
  18 REQUIRED_USE="vala? ( introspection )"
  19
  20 BDEPEND="
  21         dev-lang/perl
  22         virtual/pkgconfig
  23         doc? ( app-doc/doxygen )
  24         introspection? ( dev-libs/gobject-introspection )
  25         test? ( ${PYTHON_DEPS} )
  26         vala? ( $(vala_depend) )
  27 "
  28 COMMON_DEPEND="
  29         dev-libs/icu:=
  30         berkdb? ( sys-libs/db:= )
  31         introspection? ( dev-libs/glib:2 )
  32 "
  33 DEPEND="${COMMON_DEPEND}
  34         introspection? ( dev-libs/libxml2:2 )
  35 "
  36 RDEPEND="${COMMON_DEPEND}
  37         sys-libs/timezone-data
  38 "
  39
  40 DOCS=(
  41         AUTHORS ReadMe.txt ReleaseNotes.txt TEST THANKS TODO
  42         doc/{AddingOrModifyingComponents,UsingLibical}.txt
  43 )
  44
  45 PATCHES=(
  46         "${FILESDIR}/${PN}-3.0.4-tests.patch"
  47         "${FILESDIR}/${PN}-3.0.5-pkgconfig-libdir.patch"
  48 )
  49
  50 pkg_setup() {
  51         use test && python-any-r1_pkg_setup
  52 }
  53
  54 src_prepare() {
  55         cmake-utils_src_prepare
  56         use examples || cmake_comment_add_subdirectory examples
  57         use vala && vala_src_prepare
  58 }
  59
  60 src_configure() {
  61         local mycmakeargs=(
  62                 $(cmake-utils_use_find_package berkdb BDB)
  63                 -DICAL_BUILD_DOCS=$(usex doc)
  64                 -DICAL_GLIB=$(usex introspection)
  65                 -DGOBJECT_INTROSPECTION=$(usex introspection)
  66                 -DSHARED_ONLY=$(usex !static-libs)
  67                 -DLIBICAL_BUILD_TESTING=$(usex test)
  68                 -DICAL_GLIB_VAPI=$(usex vala)
  69         )
  70         if use vala; then
  71                 mycmakeargs+=(
  72                         -DVALAC="${VALAC}"
  73                         -DVAPIGEN="${VAPIGEN}"
  74                 )
  75         fi
  76         cmake-utils_src_configure
  77 }
  78
  79 src_compile() {
  80         cmake-utils_src_compile
  81         use doc && cmake-utils_src_compile docs
  82 }
  83
  84 src_test() {
  85         local myctestargs=(
  86                 -E "(icalrecurtest|icalrecurtest-r)" # bug 660282
  87         )
  88
  89         cmake-utils_src_test
  90 }
  91
  92 src_install() {
  93         use doc && HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
  94
  95         cmake-utils_src_install
  96
  97         if use examples; then
  98                 rm examples/CMakeLists.txt || die
  99                 dodoc -r examples
 100         fi
 101 }