dev-libs/libical/libical-3.0.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_{4,5,6} )
   7 inherit cmake-utils python-any-r1
   8
   9 DESCRIPTION="An implementation of basic iCAL protocols"
  10 HOMEPAGE="https://github.com/libical/libical"
  11 SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
  14 SLOT="0/3"
  15 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  16 IUSE="berkdb doc examples static-libs test"
  17
  18 # TODO: disabled until useful
  19 #       glib? (
  20 #               dev-libs/glib:2
  21 #               dev-libs/libxml2:2
  22 #       )
  23 #       introspection? ( dev-libs/gobject-introspection:= )
  24 COMMON_DEPEND="
  25         dev-libs/icu:=
  26         berkdb? ( sys-libs/db:= )
  27 "
  28 DEPEND="${COMMON_DEPEND}
  29         dev-lang/perl
  30         doc? ( app-doc/doxygen )
  31         test? ( ${PYTHON_DEPS} )
  32 "
  33 RDEPEND="${COMMON_DEPEND}
  34         sys-libs/timezone-data
  35 "
  36
  37 DOCS=(
  38         AUTHORS ReadMe.txt ReleaseNotes.txt TEST THANKS TODO
  39         doc/{AddingOrModifyingComponents,UsingLibical}.txt
  40 )
  41
  42 PATCHES=( "${FILESDIR}/${P}-pkgconfig-libdir.patch" )
  43
  44 pkg_setup() {
  45         use test && python-any-r1_pkg_setup
  46 }
  47
  48 src_prepare() {
  49         cmake-utils_src_prepare
  50
  51         use doc || cmake_comment_add_subdirectory doc
  52         use examples || cmake_comment_add_subdirectory examples
  53 }
  54
  55 src_configure() {
  56         local mycmakeargs=(
  57                 -DICAL_GLIB=OFF
  58                 -DGOBJECT_INTROSPECTION=OFF
  59                 $(cmake-utils_use_find_package berkdb BDB)
  60                 -DSHARED_ONLY=$(usex !static-libs)
  61         )
  62 #       TODO: disabled until useful
  63 #               -DICAL_GLIB=$(usex glib)
  64 #               -DGOBJECT_INTROSPECTION=$(usex introspection)
  65         cmake-utils_src_configure
  66 }
  67
  68 src_compile() {
  69         cmake-utils_src_compile
  70         use doc && cmake-utils_src_compile docs
  71 }
  72
  73 src_test() {
  74         local myctestargs=( -j1 )
  75         cmake-utils_src_test
  76 }
  77
  78 src_install() {
  79         use doc && HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
  80
  81         cmake-utils_src_install
  82
  83         if use examples; then
  84                 rm examples/CMakeLists.txt || die
  85                 dodoc -r examples
  86         fi
  87 }