dev-libs/libgpg-error/libgpg-error-1.27-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils libtool multilib-minimal toolchain-funcs
   7
   8 DESCRIPTION="Contains error handling functions used by GnuPG software"
   9 HOMEPAGE="http://www.gnupg.org/related_software/libgpg-error"
  10 SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2 LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="alpha ~amd64 ~arm ~arm64 ~hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="common-lisp nls static-libs"
  16
  17 RDEPEND="nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
  18         abi_x86_32? (
  19                 !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
  20                 !<=app-emulation/emul-linux-x86-baselibs-20131008-r12
  21         )"
  22 DEPEND="${RDEPEND}
  23         nls? ( sys-devel/gettext )"
  24
  25 MULTILIB_CHOST_TOOLS=(
  26         /usr/bin/gpg-error-config
  27 )
  28 MULTILIB_WRAPPED_HEADERS=(
  29         /usr/include/gpg-error.h
  30         /usr/include/gpgrt.h
  31 )
  32
  33 src_prepare() {
  34         default
  35         elibtoolize
  36 }
  37
  38 multilib_src_configure() {
  39         ECONF_SOURCE="${S}" econf \
  40                 CC_FOR_BUILD=$(tc-getBUILD_CC) \
  41                 --enable-threads \
  42                 $(use_enable nls) \
  43                 $(use_enable static-libs static) \
  44                 $(use_enable common-lisp languages) \
  45                 $(multilib_is_native_abi || echo --disable-languages)
  46 }
  47
  48 multilib_src_install_all() {
  49         einstalldocs
  50         prune_libtool_files --all
  51 }