dev-libs/libgdata/libgdata-0.17.8.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 VALA_USE_DEPEND="vapigen"
   6
   7 inherit gnome2 vala
   8
   9 DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="0/22" # subslot = libgdata soname version
  14
  15 IUSE="+crypt gnome-online-accounts +introspection static-libs test vala"
  16 REQUIRED_USE="
  17         gnome-online-accounts? ( crypt )
  18         vala? ( introspection )
  19 "
  20
  21 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  22
  23 # configure checks for gtk:3, but only uses it for demos which are not installed
  24 RDEPEND="
  25         >=dev-libs/glib-2.38.0:2
  26         >=dev-libs/json-glib-0.15
  27         >=dev-libs/libxml2-2:2
  28         >=net-libs/liboauth-0.9.4
  29         >=net-libs/libsoup-2.55.90:2.4[introspection?]
  30         >=x11-libs/gdk-pixbuf-2.14:2
  31         crypt? ( app-crypt/gcr:= )
  32         gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
  33         introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
  34 "
  35 DEPEND="${RDEPEND}
  36         >=dev-util/gtk-doc-am-1.25
  37         >=dev-util/intltool-0.40
  38         virtual/pkgconfig
  39         test? ( >=net-libs/uhttpmock-0.5 )
  40         vala? ( $(vala_depend) )
  41 "
  42
  43 src_prepare() {
  44         use vala && vala_src_prepare
  45         gnome2_src_prepare
  46 }
  47
  48 src_configure() {
  49         gnome2_src_configure \
  50                 $(use_enable crypt gnome) \
  51                 $(use_enable gnome-online-accounts goa) \
  52                 $(use_enable introspection) \
  53                 $(use_enable vala) \
  54                 $(use_enable static-libs static) \
  55                 $(use_enable test always-build-tests)
  56 }
  57
  58 src_test() {
  59         unset ORBIT_SOCKETDIR
  60         export GSETTINGS_BACKEND="memory" #486412
  61         dbus-launch emake check
  62 }