dev-libs/libgcrypt-compat/libgcrypt-compat-1.5.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools multilib-minimal
   7
   8 MY_PN="${PN%-compat}"
   9 MY_P="${MY_PN}-${PV}"
  10
  11 DESCRIPTION="Old version of libgcrypt needed by some binaries"
  12 HOMEPAGE="http://www.gnupg.org/"
  13 SRC_URI="mirror://gnupg/${MY_PN}/${MY_P}.tar.bz2"
  14 LICENSE="LGPL-2.1 MIT"
  15 SLOT="11" # soname major version
  16 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17
  18 RDEPEND=">=dev-libs/libgpg-error-1.12[${MULTILIB_USEDEP}]
  19         !dev-libs/libgcrypt:0/11
  20         !dev-libs/libgcrypt:11/11"
  21
  22 DEPEND="${RDEPEND}"
  23
  24 S="${WORKDIR}/${MY_P}"
  25
  26 PATCHES=(
  27         "${FILESDIR}"/${MY_PN}-1.5.0-uscore.patch
  28         "${FILESDIR}"/${MY_PN}-1.5.4-clang-arm.patch
  29 )
  30
  31 src_prepare() {
  32         default
  33         eautoreconf
  34 }
  35
  36 multilib_src_configure() {
  37         local myeconfargs=(
  38                 --disable-padlock-support # bug 201917
  39                 --enable-noexecstack
  40                 --disable-O-flag-munging
  41
  42                 # disabled due to various applications requiring privileges
  43                 # after libgcrypt drops them (bug #468616)
  44                 --without-capabilities
  45
  46                 # http://trac.videolan.org/vlc/ticket/620
  47                 # causes bus-errors on sparc64-solaris
  48                 $([[ ${CHOST} == *86*-darwin* ]] && echo "--disable-asm")
  49                 $([[ ${CHOST} == sparcv9-*-solaris* ]] && echo "--disable-asm")
  50         )
  51         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  52 }
  53
  54 multilib_src_install() {
  55         emake -C src DESTDIR="${D}" install-libLTLIBRARIES
  56         rm -v "${ED}"/usr/$(get_libdir)/*.{la,so} || die
  57 }