dev-libs/libffi/libffi-3.2.1-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils libtool multilib multilib-minimal toolchain-funcs
   6
   7 DESCRIPTION="a portable, high level programming interface to various calling conventions"
   8 HOMEPAGE="https://sourceware.org/libffi/"
   9 SRC_URI="ftp://sourceware.org/pub/${PN}/${P}.tar.gz"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  14 IUSE="debug pax_kernel static-libs test"
  15
  16 RDEPEND=""
  17 DEPEND="test? ( dev-util/dejagnu )"
  18
  19 DOCS="ChangeLog* README"
  20
  21 PATCHES=(
  22         "${FILESDIR}"/${PN}-3.2.1-o-tmpfile-eacces.patch #529044
  23         "${FILESDIR}"/${PN}-3.2.1-complex_alpha.patch
  24         "${FILESDIR}"/${PN}-3.1-darwin-x32.patch
  25         "${FILESDIR}"/${PN}-3.2.1-complex-ia64.patch
  26         "${FILESDIR}"/${PN}-3.2.1-include-path.patch
  27         "${FILESDIR}"/${PN}-3.2.1-include-path-autogen.patch
  28         "${FILESDIR}"/${PN}-3.2.1-ia64-small-struct.patch #634190
  29 )
  30
  31 ECONF_SOURCE=${S}
  32
  33 pkg_setup() {
  34         # Check for orphaned libffi, see https://bugs.gentoo.org/354903 for example
  35         if [[ ${ROOT} == "/" && ${EPREFIX} == "" ]] && ! has_version ${CATEGORY}/${PN}; then
  36                 local base="${T}"/conftest
  37                 echo 'int main() { }' > "${base}".c
  38                 $(tc-getCC) -o "${base}" "${base}".c -lffi >&/dev/null
  39                 if [ $? -eq 0 ]; then
  40                         eerror "The linker reported linking against -lffi to be working while it shouldn't have."
  41                         eerror "This is wrong and you should find and delete the old copy of libffi before continuing."
  42                         die "The system is in inconsistent state with unknown libffi installed."
  43                 fi
  44         fi
  45 }
  46
  47 src_prepare() {
  48         default
  49
  50         sed -i -e 's:@toolexeclibdir@:$(libdir):g' Makefile.in || die #462814
  51         elibtoolize
  52 }
  53
  54 multilib_src_configure() {
  55         use userland_BSD && export HOST="${CHOST}"
  56         # python does not like miltilib-wrapped headers: bug #643582
  57         # thus we install includes into ABI-specific paths
  58         local includes="${EPREFIX}"/usr/$(get_libdir)/${P}/include/
  59         econf \
  60                 $(use_enable static-libs static) \
  61                 $(use_enable pax_kernel pax_emutramp) \
  62                 $(use_enable debug) \
  63                 --includedir="${includes}"
  64 }
  65
  66 multilib_src_install_all() {
  67         prune_libtool_files
  68         einstalldocs
  69 }