dev-libs/libffi/libffi-3.2.1-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils libtool multilib multilib-minimal toolchain-funcs
   6
   7 DESCRIPTION="a portable, high level programming interface to various calling conventions"
   8 HOMEPAGE="https://sourceware.org/libffi/"
   9 SRC_URI="ftp://sourceware.org/pub/${PN}/${P}.tar.gz"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  14 IUSE="debug pax_kernel static-libs test"
  15
  16 RDEPEND=""
  17 DEPEND="test? ( dev-util/dejagnu )"
  18
  19 DOCS="ChangeLog* README"
  20
  21 PATCHES=(
  22         "${FILESDIR}"/${PN}-3.2.1-o-tmpfile-eacces.patch #529044
  23         "${FILESDIR}"/${PN}-3.2.1-complex_alpha.patch
  24         "${FILESDIR}"/${PN}-3.1-darwin-x32.patch
  25         "${FILESDIR}"/${PN}-3.2.1-complex-ia64.patch
  26         "${FILESDIR}"/${PN}-3.2.1-include-path.patch
  27         "${FILESDIR}"/${PN}-3.2.1-include-path-autogen.patch
  28 )
  29
  30 ECONF_SOURCE=${S}
  31
  32 pkg_setup() {
  33         # Check for orphaned libffi, see https://bugs.gentoo.org/354903 for example
  34         if [[ ${ROOT} == "/" && ${EPREFIX} == "" ]] && ! has_version ${CATEGORY}/${PN}; then
  35                 local base="${T}"/conftest
  36                 echo 'int main() { }' > "${base}".c
  37                 $(tc-getCC) -o "${base}" "${base}".c -lffi >&/dev/null
  38                 if [ $? -eq 0 ]; then
  39                         eerror "The linker reported linking against -lffi to be working while it shouldn't have."
  40                         eerror "This is wrong and you should find and delete the old copy of libffi before continuing."
  41                         die "The system is in inconsistent state with unknown libffi installed."
  42                 fi
  43         fi
  44 }
  45
  46 src_prepare() {
  47         default
  48
  49         sed -i -e 's:@toolexeclibdir@:$(libdir):g' Makefile.in || die #462814
  50         elibtoolize
  51 }
  52
  53 multilib_src_configure() {
  54         use userland_BSD && export HOST="${CHOST}"
  55         # python does not like miltilib-wrapped headers: bug #643582
  56         # thus we install includes into ABI-specific paths
  57         local includes="${EPREFIX}"/usr/$(get_libdir)/${P}/include/
  58         econf \
  59                 $(use_enable static-libs static) \
  60                 $(use_enable pax_kernel pax_emutramp) \
  61                 $(use_enable debug) \
  62                 --includedir="${includes}"
  63 }
  64
  65 multilib_src_install_all() {
  66         prune_libtool_files
  67         einstalldocs
  68 }