dev-libs/libev/libev-4.22.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools eutils multilib-minimal
   7
   8 DESCRIPTION="A high-performance event loop/event model with lots of feature"
   9 HOMEPAGE="http://software.schmorp.de/pkg/libev.html"
  10 SRC_URI="http://dist.schmorp.de/libev/${P}.tar.gz
  11         http://dist.schmorp.de/libev/Attic/${P}.tar.gz"
  12
  13 LICENSE="|| ( BSD GPL-2 )"
  14 SLOT="0"
  15 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  16 IUSE="elibc_glibc static-libs"
  17
  18 # Bug #283558
  19 DEPEND="elibc_glibc? ( >=sys-libs/glibc-2.9_p20081201 )"
  20 RDEPEND="${DEPEND}"
  21
  22 DOCS=( Changes README )
  23
  24 src_prepare() {
  25         sed -i -e "/^include_HEADERS/s/ event.h//" Makefile.am || die
  26
  27         # bug #411847
  28         epatch "${FILESDIR}/${PN}-pc.patch"
  29
  30         epatch_user
  31         eautoreconf
  32 }
  33
  34 multilib_src_configure() {
  35         ECONF_SOURCE="${S}" \
  36         econf \
  37                 --disable-maintainer-mode \
  38                 $(use_enable static-libs static)
  39 }
  40
  41 multilib_src_install_all() {
  42         use static-libs || prune_libtool_files
  43         einstalldocs
  44 }