dev-libs/libdivsufsort/libdivsufsort-9999.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 EGIT_REPO_URI="https://github.com/y-256/${PN}"
   6 inherit cmake-utils multilib toolchain-funcs git-r3
   7
   8 DESCRIPTION="Suffix-sorting library (for BWT)"
   9 HOMEPAGE="https://github.com/y-256/libdivsufsort"
  10 SRC_URI=""
  11
  12 LICENSE="MIT"
  13 SLOT="0"
  14 KEYWORDS=""
  15 IUSE="openmp"
  16
  17 pkg_pretend() {
  18         [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
  19 }
  20
  21 pkg_setup() {
  22         [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
  23 }
  24
  25 src_prepare() {
  26         cmake-utils_src_prepare
  27
  28         # will appreciate saner approach, if there is any
  29         sed -i -e "s:\(DESTINATION \)lib:\1$(get_libdir):" \
  30                 */CMakeLists.txt || die
  31 }
  32
  33 src_configure() {
  34         local mycmakeargs=("-DBUILD_DIVSUFSORT64=ON" "-DUSE_OPENMP=$(usex openmp)")
  35         cmake-utils_src_configure
  36 }