dev-libs/libcroco/libcroco-0.6.9.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7 GNOME2_LA_PUNT="yes"
   8
   9 inherit gnome2 multilib-minimal
  10
  11 DESCRIPTION="Generic Cascading Style Sheet (CSS) parsing and manipulation toolkit"
  12 HOMEPAGE="https://git.gnome.org/browse/libcroco/"
  13
  14 LICENSE="LGPL-2"
  15 SLOT="0.6"
  16 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="test"
  18
  19 RDEPEND="
  20         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  21         >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
  22 "
  23 DEPEND="${RDEPEND}
  24         dev-util/gtk-doc-am
  25         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  26 "
  27
  28 src_prepare() {
  29         if ! use test; then
  30                 # don't waste time building tests
  31                 sed 's/^\(SUBDIRS .*\=.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  32                         || die "sed failed"
  33         fi
  34
  35         gnome2_src_prepare
  36 }
  37
  38 multilib_src_configure() {
  39         ECONF_SOURCE=${S} \
  40         gnome2_src_configure \
  41                 --disable-static \
  42                 $([[ ${CHOST} == *-darwin* ]] && echo --disable-Bsymbolic)
  43
  44         if multilib_is_native_abi; then
  45                 ln -s "${S}"/docs/reference/html docs/reference/html || die
  46         fi
  47 }
  48
  49 multilib_src_install() {
  50         gnome2_src_install
  51 }
  52
  53 multilib_src_install_all() {
  54         DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"
  55         einstalldocs
  56 }