dev-libs/libcroco/libcroco-0.6.8-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7 GNOME2_LA_PUNT="yes"
   8
   9 inherit gnome2 multilib-minimal
  10
  11 DESCRIPTION="Generic Cascading Style Sheet (CSS) parsing and manipulation toolkit"
  12 HOMEPAGE="https://git.gnome.org/browse/libcroco/"
  13
  14 LICENSE="LGPL-2"
  15 SLOT="0.6"
  16 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="test"
  18
  19 RDEPEND=">=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  20         >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]"
  21 DEPEND="${RDEPEND}
  22         dev-util/gtk-doc-am
  23         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
  24
  25 src_prepare() {
  26         if ! use test; then
  27                 # don't waste time building tests
  28                 sed 's/^\(SUBDIRS .*\=.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  29                         || die "sed failed"
  30         fi
  31
  32         gnome2_src_prepare
  33 }
  34
  35 multilib_src_configure() {
  36         ECONF_SOURCE=${S} \
  37         gnome2_src_configure \
  38                 --disable-static \
  39                 $([[ ${CHOST} == *-darwin* ]] && echo --disable-Bsymbolic)
  40
  41         if multilib_is_native_abi; then
  42                 ln -s "${S}"/docs/reference/html docs/reference/html || die
  43         fi
  44 }
  45
  46 multilib_src_install() {
  47         gnome2_src_install
  48 }
  49
  50 multilib_src_install_all() {
  51         DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"
  52         einstalldocs
  53 }