dev-libs/libcoyotl/libcoyotl-3.1.0-r2.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit eutils autotools
   7
   8 DESCRIPTION="A collection of portable C++ classes"
   9 HOMEPAGE="http://www.coyotegulch.com/products/libcoyotl/"
  10 SRC_URI="http://www.coyotegulch.com/distfiles/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux"
  15
  16 IUSE="doc static-libs"
  17
  18 RDEPEND="media-libs/libpng:0="
  19 DEPEND="${RDEPEND}
  20         doc? ( app-doc/doxygen )"
  21
  22 DOCS=( AUTHORS ChangeLog NEWS README )
  23
  24 src_prepare() {
  25         epatch "${FILESDIR}/${PV}-gcc-4.3.patch"
  26         epatch "${FILESDIR}/${PV}-gcc-4.7.patch"
  27         epatch_user
  28         eautoreconf
  29 }
  30
  31 src_configure() {
  32         ac_cv_prog_HAVE_DOXYGEN="false" econf $(use_enable static-libs static)
  33 }
  34
  35 src_compile() {
  36         emake
  37
  38         if use doc ; then
  39                 cd docs
  40                 doxygen libcoyotl.doxygen || die "generating docs failed"
  41         fi
  42 }
  43
  44 src_install() {
  45         default
  46         prune_libtool_files
  47         if use doc ; then
  48                 dohtml docs/html/*
  49         fi
  50 }