dev-libs/libcdio/libcdio-0.93.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils libtool multilib-minimal
   7
   8 DESCRIPTION="A library to encapsulate CD-ROM reading and control"
   9 HOMEPAGE="https://www.gnu.org/software/libcdio/"
  10 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0/15" # subslot is based on SONAME
  14 KEYWORDS="alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  15 IUSE="cddb +cxx minimal static-libs test"
  16
  17 RDEPEND="
  18         !minimal? (
  19                 >=sys-libs/ncurses-5.7-r7:0=
  20                 cddb? ( >=media-libs/libcddb-1.3.2 )
  21         )
  22         >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
  23         abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r10
  24                 !app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
  25 DEPEND="${RDEPEND}
  26         sys-apps/sed
  27         sys-devel/gettext
  28         virtual/pkgconfig
  29         test? ( dev-lang/perl )"
  30 DOCS="AUTHORS ChangeLog NEWS README* THANKS TODO"
  31
  32 MULTILIB_WRAPPED_HEADERS=(
  33         /usr/include/cdio/cdio_config.h
  34         /usr/include/cdio/version.h
  35 )
  36
  37 src_prepare() {
  38         sed \
  39                 -e "s:-lncurses:$($(tc-getPKG_CONFIG) --libs ncurses):g" \
  40                 -i configure || die
  41
  42         elibtoolize # to prevent -L/usr/lib ending up in the linker line wrt 499510
  43 }
  44
  45 multilib_src_configure() {
  46         local util_switch
  47         if ! multilib_is_native_abi || use minimal ; then
  48                 util_switch="--without"
  49         else
  50                 util_switch="--with"
  51         fi
  52
  53         # Tests fail if ECONF_SOURCE is not relative
  54         ECONF_SOURCE="../${P}" econf \
  55                 --disable-maintainer-mode \
  56                 $(use_enable cxx) \
  57                 --disable-cpp-progs \
  58                 --disable-example-progs \
  59                 $(use_enable static-libs static) \
  60                 $(use_enable cddb) \
  61                 --disable-vcd-info \
  62                 ${util_switch}-{cd-drive,cd-info,cdda-player,cd-read,iso-info,iso-read}
  63 }
  64
  65 multilib_src_install_all() {
  66         einstalldocs
  67         prune_libtool_files
  68 }