dev-libs/kqoauth/kqoauth-0.98-r2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit qmake-utils
   7
   8 DESCRIPTION="Library for Qt that implements the OAuth 1.0 authentication specification"
   9 HOMEPAGE="https://github.com/kypeli/kQOAuth"
  10 SRC_URI="https://github.com/kypeli/kQOAuth/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 DEPEND="
  18         dev-qt/qtcore:5
  19         dev-qt/qtgui:5
  20         dev-qt/qtnetwork:5
  21         dev-qt/qtxml:5
  22 "
  23 RDEPEND="${DEPEND}"
  24
  25 S="${WORKDIR}/kQOAuth-${PV}"
  26
  27 src_prepare() {
  28         default
  29
  30         # prevent tests from beeing built at src_compile
  31         sed -i -e '/SUBDIRS/s/ tests//' ${PN}.pro || die "sed on ${PN}.pro failed"
  32         # respect libdir
  33         sed -e 's:{INSTALL_PREFIX}/lib:[QT_INSTALL_LIBS]:g' -i src/src.pro || die "sed on src.pro failed"
  34
  35         sed \
  36                 -e "s/TARGET = kqoauth/TARGET = kqoauth-qt5/g" \
  37                 -i src/src.pro || die
  38 }
  39
  40 src_configure() {
  41         eqmake5
  42 }
  43
  44 src_install() {
  45         emake INSTALL_ROOT="${D}" install
  46 }