dev-libs/keybinder/keybinder-0.3.1-r300.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils
   7
   8 MY_P=${PN}-3.0-${PV}
   9
  10 DESCRIPTION="A library for registering global keyboard shortcuts"
  11 HOMEPAGE="https://github.com/engla/keybinder"
  12 SRC_URI="https://github.com/engla/keybinder/releases/download/${PN}-3.0-v${PV}/${MY_P}.tar.gz"
  13
  14 LICENSE="MIT"
  15 SLOT="3"
  16 KEYWORDS="~alpha amd64 arm ~hppa ~mips ppc ppc64 x86"
  17 IUSE="+introspection"
  18
  19 RDEPEND="x11-libs/gtk+:3
  20         x11-libs/libX11
  21         x11-libs/libXext
  22         x11-libs/libXrender
  23         introspection? ( dev-libs/gobject-introspection )"
  24 DEPEND="${RDEPEND}
  25         virtual/pkgconfig"
  26
  27 DOCS="AUTHORS NEWS README"
  28
  29 S=${WORKDIR}/${MY_P}
  30
  31 src_configure() {
  32         econf \
  33                 $(use_enable introspection) \
  34                 --with-html-dir="${EPREFIX}/usr/share/doc/${PF}/html"
  35 }
  36
  37 src_install() {
  38         default
  39         prune_libtool_files --all
  40         dosym /usr/share/doc/${PF}/html/${PN}-3.0 /usr/share/gtk-doc/html/${PN}-3.0
  41 }