dev-libs/json-glib/json-glib-1.4.4.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome.org meson multilib-minimal xdg-utils
   6
   7 DESCRIPTION="Library providing GLib serialization and deserialization for the JSON format"
   8 HOMEPAGE="https://wiki.gnome.org/Projects/JsonGlib"
   9
  10 LICENSE="LGPL-2.1+"
  11 SLOT="0"
  12 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ia64 ~mips ~ppc ~ppc64 ~s390 sparc ~x86 ~amd64-fbsd ~x86-fbsd"
  13 IUSE="gtk-doc +introspection"
  14
  15 RDEPEND="
  16         >=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
  17         introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
  18 "
  19 # TODO: Can we use a newer docbook-xml-dtd, or is one needed at all?
  20 DEPEND="${RDEPEND}
  21         ~app-text/docbook-xml-dtd-4.1.2
  22         app-text/docbook-xsl-stylesheets
  23         dev-libs/libxslt
  24         dev-util/glib-utils
  25         gtk-doc? ( >=dev-util/gtk-doc-1.20 )
  26         >=sys-devel/gettext-0.18
  27         virtual/pkgconfig[${MULTILIB_USEDEP}]
  28 "
  29
  30 src_prepare() {
  31         xdg_environment_reset
  32         default
  33         # Disable installed-tests; this also indirectly removes build_aux/gen-installed-test.py calls, thus not needing python-any-r1.eclass
  34         sed -e 's/install: true/install: false/g' -i json-glib/tests/meson.build || die
  35         sed -e '/install_data/d' -i json-glib/tests/meson.build || die
  36 }
  37
  38 multilib_src_configure() {
  39         local emesonargs=(
  40                 -Dintrospection=$(multilib_native_usex introspection true false)
  41                 -Ddocs=$(multilib_native_usex gtk-doc true false)
  42                 -Dman=true
  43         )
  44         meson_src_configure
  45 }
  46
  47 multilib_src_compile() {
  48         meson_src_compile
  49 }
  50
  51 multilib_src_install() {
  52         meson_src_install
  53 }
  54
  55 multilib_src_test() {
  56         meson_src_test
  57 }