dev-libs/intel-neo/intel-neo-19.30.13641.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake-utils
   7
   8 MY_PN="compute-runtime"
   9 MY_P="${MY_PN}-${PV}"
  10
  11 DESCRIPTION="Intel Graphics Compute Runtime for OpenCL, for Gen8 (Broadwell) and beyond"
  12 HOMEPAGE="https://github.com/intel/compute-runtime"
  13 SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64"
  18 IUSE="vaapi"
  19
  20 BDEPEND="virtual/pkgconfig"
  21 COMMON="dev-libs/ocl-icd
  22         dev-util/intel-graphics-compiler
  23         >=media-libs/gmmlib-19.0.0
  24         vaapi? (
  25                 x11-libs/libdrm[video_cards_intel]
  26                 >=x11-libs/libva-2.0.0
  27         )"
  28 DEPEND="${COMMON}
  29         media-libs/mesa"        # for Khronos OpenGL headers
  30 RDEPEND="${COMMON}"
  31
  32 DOCS=(
  33         README.md
  34         documentation/FAQ.md
  35         documentation/LIMITATIONS.md
  36 )
  37
  38 PATCHES=(
  39         "${FILESDIR}"/${PN}-19.16.12873_cmake_no_libva_automagic.patch
  40 )
  41
  42 S="${WORKDIR}"/${MY_P}
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 -DKHRONOS_GL_HEADERS_DIR="${EPREFIX}/usr/include"
  47                 -DENABLE_VAAPI_MEDIA_SHARING=$(usex vaapi "ON" "OFF")
  48                 # If enabled, tests are automatically run during the compile phase
  49                 # - and we cannot run them because they require permissions to access
  50                 # the hardware.
  51                 -DSKIP_UNIT_TESTS=ON
  52         )
  53         cmake-utils_src_configure
  54 }
  55
  56 pkg_postinst() {
  57         "${ROOT}"/usr/bin/eselect opencl set --use-old ocl-icd
  58 }