dev-libs/gobject-introspection/gobject-introspection-1.56.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
   6 PYTHON_REQ_USE="xml"
   7
   8 inherit gnome2 python-single-r1 toolchain-funcs
   9
  10 DESCRIPTION="Introspection system for GObject-based libraries"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
  12
  13 LICENSE="LGPL-2+ GPL-2+"
  14 SLOT="0"
  15 IUSE="cairo doctool test"
  16 REQUIRED_USE="
  17         ${PYTHON_REQUIRED_USE}
  18         test? ( cairo )
  19 "
  20 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21
  22 # virtual/pkgconfig needed at runtime, bug #505408
  23 # We force glib and g-i to be in sync by this way as explained in bug #518424
  24 RDEPEND="
  25         >=dev-libs/gobject-introspection-common-${PV}
  26         >=dev-libs/glib-2.56.1:2
  27         doctool? ( dev-python/mako[${PYTHON_USEDEP}] )
  28         virtual/libffi:=
  29         virtual/pkgconfig
  30         !<dev-lang/vala-0.20.0
  31         ${PYTHON_DEPS}
  32 "
  33 # Wants real bison, not virtual/yacc
  34 DEPEND="${RDEPEND}
  35         >=dev-util/gtk-doc-am-1.19
  36         sys-devel/bison
  37         sys-devel/flex
  38         test? ( x11-libs/cairo[glib] )
  39 "
  40 # PDEPEND to avoid circular dependencies, bug #391213; but needed for tests, thus test DEPEND as well
  41 PDEPEND="cairo? ( x11-libs/cairo[glib] )"
  42
  43 pkg_setup() {
  44         python-single-r1_pkg_setup
  45 }
  46
  47 src_configure() {
  48         if ! has_version "x11-libs/cairo[glib]"; then
  49                 # Bug #391213: enable cairo-gobject support even if it's not installed
  50                 # We only PDEPEND on cairo to avoid circular dependencies
  51                 export CAIRO_LIBS="-lcairo -lcairo-gobject"
  52                 export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
  53         fi
  54
  55         # To prevent crosscompiling problems, bug #414105
  56         gnome2_src_configure \
  57                 --disable-static \
  58                 CC="$(tc-getCC)" \
  59                 YACC="$(type -p yacc)" \
  60                 $(use_with cairo) \
  61                 $(use_enable doctool)
  62 }
  63
  64 src_install() {
  65         gnome2_src_install
  66
  67         # Prevent collision with gobject-introspection-common
  68         rm -v "${ED}"usr/share/aclocal/introspection.m4 \
  69                 "${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
  70         rmdir "${ED}"usr/share/aclocal || die
  71 }