dev-libs/gobject-introspection/gobject-introspection-1.50.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python{2_7,3_4,3_5} )
   6 PYTHON_REQ_USE="xml"
   7
   8 inherit gnome2 python-single-r1 toolchain-funcs versionator
   9
  10 DESCRIPTION="Introspection system for GObject-based libraries"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
  12
  13 LICENSE="LGPL-2+ GPL-2+"
  14 SLOT="0"
  15 IUSE="cairo doctool test"
  16 REQUIRED_USE="
  17         ${PYTHON_REQUIRED_USE}
  18         test? ( cairo )
  19 "
  20 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21
  22 # virtual/pkgconfig needed at runtime, bug #505408
  23 # We force glib and g-i to be in sync by this way as explained in bug #518424
  24 RDEPEND="
  25         >=dev-libs/gobject-introspection-common-${PV}
  26         >=dev-libs/glib-2.$(get_version_component_range 2):2
  27         doctool? ( dev-python/mako[${PYTHON_USEDEP}] )
  28         virtual/libffi:=
  29         virtual/pkgconfig
  30         !<dev-lang/vala-0.20.0
  31         ${PYTHON_DEPS}
  32 "
  33 # Wants real bison, not virtual/yacc
  34 DEPEND="${RDEPEND}
  35         >=dev-util/gtk-doc-am-1.19
  36         sys-devel/bison
  37         sys-devel/flex
  38 "
  39 # PDEPEND to avoid circular dependencies, bug #391213
  40 PDEPEND="cairo? ( x11-libs/cairo[glib] )"
  41
  42 pkg_setup() {
  43         python-single-r1_pkg_setup
  44 }
  45
  46 src_configure() {
  47         if ! has_version "x11-libs/cairo[glib]"; then
  48                 # Bug #391213: enable cairo-gobject support even if it's not installed
  49                 # We only PDEPEND on cairo to avoid circular dependencies
  50                 export CAIRO_LIBS="-lcairo -lcairo-gobject"
  51                 export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
  52         fi
  53
  54         # To prevent crosscompiling problems, bug #414105
  55         gnome2_src_configure \
  56                 --disable-static \
  57                 CC="$(tc-getCC)" \
  58                 YACC="$(type -p yacc)" \
  59                 $(use_with cairo) \
  60                 $(use_enable doctool)
  61 }
  62
  63 src_install() {
  64         gnome2_src_install
  65
  66         # Prevent collision with gobject-introspection-common
  67         rm -v "${ED}"usr/share/aclocal/introspection.m4 \
  68                 "${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
  69         rmdir "${ED}"usr/share/aclocal || die
  70 }